1. Рассчитаем помощь малооплачиваемым. Сначала найдем ее в предположении, что выделенная сумма покрывает необходимые доплаты. Назовем ее максимально возможной помощью

помощь_максимальная=если(зарплата<5*мин._зарплата, то 5*мин._зарплата – зарплата, иначе 0).

	A	B	C	D	E
1	Премия:	800		Мин.зарп:	100
2	РАСПРЕДЕЛЕНИЕ ПРЕМИИ
3	Имя	Зарп- лата	Помощь		Итого
4			максим.	фактич.
5	Петр	400	100	100	120
6	Ольга	1200	0	0	60
7	Иван	300	200	200	215
8	Олег	100	400	400	405
9	Всего	2000	700	700	800
		Рис.	5.16а

Она будет таковой, если общая сумма помощи достаточна. Если денег выделено меньше, то помощь уменьшается до выделенного значения и делится пропорционально планируемым максимальным суммам помощи

помощь_фактическая=если(

общая_максимальная_помощь < премии,

то помощь_максимальная, иначе помощь_

максимальная*премия/общая_максимальная_помощь).

2. Остаток премии (если есть) делится уже между всеми работниками (включая и малооплачиваемых) пропорционально их зарплате

итого=если(общая_фактическая_помощь<премии, то

(помощь – общая_фактическая_помощь)/

общая_зарплата*зарплата) + помощь_фактическая.

Правильность расчетов подтверждает то, что B1=E9.

A

B

C

D

E

	A	B
1	Дата	Цена $
2	04.янв	21,1р
3	05.янв	22,2р
4	06.янв	22,4р
5	07.янв	22,6р
6	08.янв	22,3р
7	11.янв	22,6р
8	12.янв	22,8р

Рис. 5.17а. Лист Курс

1

Премия:

800

Мин.зарп:

100

2

РАСПРЕДЕЛЕНИЕ ПРЕМИИ

3

Имя

Зарплата

Помощь

Итого

4

максим.

фактич.

5

Петр

400

=ЕСЛИ(B5<5*

E$1;5*E$1–B5;0)

=ЕСЛИ(C$9<=B$1;

C5;C5*B$1/$C$9)

=ЕСЛИ(D$9<B$1;

(B$1–D$9)/B$9*B5)+D5

. . .

8

Олег

100

=ЕСЛИ(B8<5*

E$1;5*E$1–B8;0)

=ЕСЛИ(C$9<=B$1;

C8;C8*B$1/C$9)

=ЕСЛИ(D$9<B$1;

(B$1–D$9)/B$9*B8)+D8

9

Всего

=СУММ(B5:B8)

=СУММ(C5:C8)

=СУММ(D5:D8)

=СУММ(E5:E8)

Рис. 5.16б

	A	B	C	D	E	F
1	Сегодня:	13.янв
2	Товар закуплен	Цена закупки	Дата и курс конвертиров.		Цена закупки	Цена сегодня
3	04.янв	100$	04.янв	21,1р	2 110р	2 280р
4	06.янв	50$	06.янв	22,4р	1 120р	1 140р
5	09.янв	80$	08.янв	22,3р	1 784р	1 824р
6	10.янв	30$	08.янв	22,3р	669р	684р
7	11.янв	70$	11.янв	22,6р	1 582р	1 596р
8	12.янв	100$	12.янв	22,8р	2 280р	2 280р
Рис. 5.17б. Лист Товар

	B	C	D	E	F
1	=СЕГОДНЯ()
2	Цена закупки	Дата и курс конвертирования		Цена закупки	Цена сегодня
3	100$	=ВПР(A3;Курс! A$2:B$240;1;1)	=ВПР(A3;Курс! A$2:B$240;2;1)	=D3*B3	=ВПР(B$1;Курс! A$2:B$240;2;1)*B3
4	50$	=ВПР(A4;Курс! A$2:B$240;1;1)	=ВПР(A4;Курс! A$2:B$240;2;1)	=D4*B4	=ВПР(B$1;Курс! A$2:B$240;2;1)*B4
5	80$	=ВПР(A5;Курс! A$2:B$240;1;1)	=ВПР(A5;Курс! A$2:B$240;2;1)	=D5*B5	=ВПР(B$1;Курс! A$2:B$240;2;1)*B5
		Рис. 5.17в.	Лист Товар

Пример 5.17. Конвертирование валюты. Создать таблицу конвертирования цены товара. При внешнеторговых операциях расчет с поставщиками выполняется в долларах, а расчет с внутренними покупателями – в рублях. Ввиду этого нужно иметь возможность конвертирования в рубли исходной (в момент поступления) и текущей (“на сегодня”) цены товара. Вся необходимая информация хранится в двух таблицах: таблице курса доллара и таблице расчета рублевого эквивалента товара. Для удобства пользователя этот материал мы разнесем на два листа рабочей книги – лист Курс и лист Товар. Содержимое первого (на рисунке изображен только фрагмент листа) очевидно, – это последовательные значения дат и стоимости доллара.

	A	B	C	D
1	Дата	Курс $	Курс DM	Курс ₤
2	04.янв	21,1р	16,9р	30,4р
3	05.янв	22,2р	17,8р	32,0р
4	06.янв	22,4р	17,9р	32,2р
5	07.янв	22,6р	18,1р	32,6р
6	08.янв	22,3р	17,8р	32,0р
7	11.янв	22,6р	18,1р	32,6р
8	12.янв	22,8р	18,2р	32,8р

Рис. 5.18а. Лист Курс

На листе Товар в В1 предъявляется текущая дата (функция СЕГОДНЯ()), а также содержатся сведения о дате закупки товара и его закупочной цене (столбцы А и В). В столбце Е вычисляется рублевый эквивалент этой цены, но прежде формируются два столбца, нужные только для сведения оператора. В столбце С предъявляется ближайшая, найденная в листе Курс, дата (С3=ВПР(A3;Курс!A$2:B$240;1;1)), по курсу которой (столбец D) и производится конвертирование долларов в рубли. Делается это ради того, что бы пользователь мог контролировать правильность конвертирования. Так, например, если обнаруживается что дата конвертирования сильно отстает от даты закупки, можно предположить что курсовая таблица содержит не все данные и ее следует просмотреть и, возможно, дополнить. В столбце D показывается найденный курс доллара, по которому будет осуществляться конвертирование цены товара D3=ВПР(A3;Курс!A$2:B$240; 2;1). На основании его и находится закупочная цена товара в рублях E3=D3*B3. В столбце F определяется рублевый эквивалент цены товара “на сегодня” F3=ВПР(B$1; Курс!A$2 :B$240;2;1)*B3. В обоих выражениях используется функция ВПР() с четвертым аргументом равным 1, т.е. поиск даты в таблице курса доллара будет не точным, а интервальным, поскольку некоторых дат там нет (валютная биржа не работает в выходные дни – у нас 9 и 10 января) и стоимость доллара тогда берется равной курсу ближайшей предыдущей даты (8 января), для которой она имеется. В качестве области поиска определена область листа Курс, содержащая два столбца А и В и число строк, равное числу рабочих дней в году (около 240).

Пример 5.18. Конвертирование в различные виды валют. Похожий пример, но покупка товара у зарубежных поставщиков может быть осуществлена не только в долларах, но также в немецких марках и в английских фунтах стерлингов, для чего в таблицу курсов валют включены соответствующие столбцы (на рисунке показана только часть листа Курс). В листе Товар введен столбец Вид валюты, где может быть задан один из символов Д, М, Ф, обозначающих доллар, марку и фунт. В колонку С вводится цена в соответствующей валюте. Рублевая цена товара находится так же, как и ранее, но номер столбца, из которого извлекается курс, зависит от символа валюты, который ищется в строке “ДМФ” с помощью функции ПОИСК(B3; "ДМФ"). Если B3 равно Д, М или Ф, результатом применения функции будет число 1, 2 или 3. Поскольку курсы этих валют находятся соответственно во второй, третьей и четвертой колонках листа Курс, для поиска в курсовой таблице к результату нужно прибавить единицу (ПОИСК(…)+1). Тогда справедливо

D3=ВПР(A3;Курс!A$2:D$241;ПОИСК(СТРОЧН(B3);"ДМФ")+1;1)*C3.

Здесь к клетке D3 применена функция преобразования строчных букв в прописные СТРОЧН(). Это позволит вводить в колонку Вид валюты не только буквы Д, М, Ф, но и д, м, ф. Ввод любого другого символа (как, например, в строке 8) порождает сообщение об ошибке вида #ЗНАЧ!, которое пользователь легко обнаружит. Аналогично находится Цена сегодня.

E3=ВПР($B$1;Курс!A$2:D$241;ПОИСК(СТРОЧН(B3);"ДМФ")+1;1)*C3.

	A	B	C	D	E
1	Сегодня:	05.фев
2	Товар закуплен	Вид валюты	Цена закупки		Цена сегодня
3	04.янв	д	100	2 110р	2 280р
4	06.янв	ф	50	1 610р	1 640р
5	09.янв	ф	80	2 560р	2 624р
6	10.янв	д	30	669р	684р
7	11.янв	м	70	1 267р	1 274р
8	12.янв	х	10	#ЗНАЧ!	#ЗНАЧ!
	Рис. 5.18б. Лист Товар

К оформлению. Существует способ гарантированно правильного ввода стабильных данных – это использование механизма Проверка из меню Данные. Условие проверки должно быть таким, как показано на рис. 5.18в (источником данных является список с буквами Д, Ф, М). А если установить в окне Проверка флаг Список допустимых значений, то возможен не только ввод “руками”, но выбор данных из списка-меню.

Пример 5.19. Турнирная таблица. Создать таблицу определения призеров по результатам чемпиона­та. Положим, в играх участвуют три команды. Для каждой игры фиксируется ее счет – число забитых и пропущенных голов (колонки “з” и “п”). В колонке “о” вычисляется число очков, полученных по результатам игры. Считается, что проигрыш приносит 0 очков, ничья – одно, выигрыш – два. Если игры еще не было, клетка остается пустой ("").

Ф ормулы для вычисления очков по игре приведены ниже

D4=ЕСЛИ(B4>C4;2;ЕСЛИ(ЕПУСТО(B4);"";ЕСЛИ(B4=C4;1;0))),

G4=ЕСЛИ(E4>F4;2;ЕСЛИ(ЕПУСТО(E4);"";ЕСЛИ(E4=F4;1;0))),

J4=ЕСЛИ(H4>I4;2;ЕСЛИ(ЕПУСТО(H4);"";ЕСЛИ(H4=I4;1;0))),

M4=ЕСЛИ(K4>L4;2;ЕСЛИ(ЕПУСТО(K4);"";ЕСЛИ(K4=L4;1;0))).

По итогам чемпионата формируются сводные данные:

1. Число сыгранных игр. Здесь подсчитывается количество всех непустых клеток в диапазоне, где фиксируются игры, и делится на три (три клетки занимаются под каждую игру). Из числа непустых ячеек вычитается единица, чтобы не учитывалась заштрихованная клетка, в которой находится формула вычисления очков, находящаяся на пересечении строки и столбца для одной и той же команды (например, D4).

	A	B	C	D Турнирная таблица	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T
1
2			Спартак			Динамо			ЦСКА			Фили		Игр	Очков	Забито	Пропущено	Разность	Очки + разность	МЕСТО
3	Команды	з	п	о	з	п	о	з	п	о	з	п	о
4	Спартак				1	1	1	2	3	0	3	4	0	3	1	6	8	–2	1,098	4
5	Динамо	1	1	1				3	2	2	2	0	2	3	5	6	3	3	5,103	1
6	ЦСКА	3	2	2	2	3	0							2	2	5	5	0	2,100	2
7	Фили	4	3	2	0	2	0							2	2	4	5	–1	2,099	3
							Рис. 5.19

2. Число всех добытых командой очков в чемпионате. Подсчитывается сумма содержимого клеток, находящихся в столбцах, где в строке В3:M3 буква “о” (очки).

3.4. Аналогично подсчитывается число забитых и пропущенных голов.

5. Разность забитых и пропущенных голов.

6. Число очков с учетом соотношения забитых и пропущенных голов. Может случиться так, что некоторые команды будут иметь одинаковое число очков по результату чемпионата (у нас ЦСКА и Фили имеют по 2 очка). В этом случае место в чемпионате определяется по лучшей (большей) разности забитых и пропущенных голов. Чтобы учесть ее влияние, к сумме очков прибавляется некоторая величина, являющаяся функцией разности. Она должна быть такой, чтобы в итоге целая часть суммы очков не изменилась (малое положительное число). Для этого к разности очков сначала прибавляется 100 (чтобы избежать возможности уменьшения числа очков, если разность отрицательна), затем результат делится на 1000 (чтобы избежать изменения целой части результата) и все это прибавляется к сумме добытых командой очков. Таким образом, ЦСКА и Фили будут иметь уже не по 2 очка, а 2,1 и 2,099 очков соответственно, что отражает лучшее положение команды ЦСКА в турнире. В дальнейшем этот столбец, служащий для технических целей, может быть скрыт от пользователя, как, кстати, и столбцы “о”.

7. Занятое место в чемпионате определяется функцией РАНГ().

Соответствующие формулы для первой команды приведены ниже

Игр сыграно: N4=(СЧЁТЗ(B4:M4)–1)/3, Очки+Разность (голов): S4=O4+(R4+100)/1000,

Очков команды: O4=СУММЕСЛИ(B$3:$M$3;"=о";B4:M4), Место (в турнире): T4=РАНГ(S4;S$4:S$7),

Забито голов: P4=СУММЕСЛИ(B$3:$M$3;"=з";B4:M4), Разность забитых и пропущенных голов: R4=P4–Q4,

Пропущено голов: Q4=СУММЕСЛИ(B$3:$M$3;"=п";B4:M4).

	A	B	C	D	E	F
1	Сумма:	0	2000	4000	6000	10000
2	Налог:	0%	12%	15%	20%	30%
3	Мин.зарп.	80
4		РАСЧЕТ НАЛОГОВ
5	Работник	Детей	Доход	Сумма обложения	Налог	Сумма на руки
6	Петр		1000	1000	0,0	1000,0
7	Иван	1	12000	11920	3576,0	8344,0
8	Олег	2	5000	4840	726,0	4114,0
9	ВСЕГО		18000	18000	5400,0	13458,0
				Рис. 5.20а

Пример 5.20. Расчет зарплаты и налогов. Построить таблицу вычисления зарплаты с учетом увеличивающегося подоходного налога и числа детей. Положим, с месячного дохода до 2000 налог не удерживается, от 2000 удерживается в сумме 12%, от 4000 – 15%, от 6000 – 20%, от 10000 – 30%. Налог удерживается не со всей суммы заработка, а с величины, мень­шей на одну минимальную зарплату, на каждого ребенка (иждивенца).

Для вычисления удержаний в таблицу внесен технический столбец Сумма обложения, где из дохода вычитается необлагаемая налогом часть

сумма_обложения=доход–детей*миним._зарплата для Петра это D6=C6–B6*B$3.

Если доход мал, сумма может оказаться меньше нуля. Чтобы не допускать отрицательных значений, используется функция вычисления максимума от двух аргументов – нуля и облагаемой суммы. Таким образом, если результат отрицательный, сумма обложения будет равна нулю (D6=МАКС(0;C6–B6*B$3)). Собственно налог находится с помощью функ­ции поиска, определяющей ближайшее меньшее к облагаемой сумме

налог=процент_налога*сумма_обложения или E6=ГПР(D6;B$1:F$2;2;1)*D6.

Чтобы поиск выполнялся нужным образом, последний аргумент в функции ГПР() – единица. Это обеспечит диапазонный поиск, в отличие от точного поиска, реализуемого в предыдущем примере. Сумма на руки есть F6=D6–E6.

Замечание: Столбец Сумма обложения введен только для упрощения формул, используемых в таблице. Однако ничто не мешает нам соединить все формулы, связанные с определением налога непосредственно в столбце Налог. Обычно, с целью экономии экранной площади, так и поступают, поскольку столбцов становится меньше.

	A	B	C	D	E	F
1	Сумма:	0	2000	4000	6000	10000
2	Налог:	0%	12%	15%	20%	30%
3	Мин. зарп.	80
4		РАСЧЕТ НАЛОГОВ
5	Работник	Детей	Доход	Сумма обложения	Налог	Сумма на руки
6	Петр		1000	=МАКС(0;C6–B6*B$3)	=ГПР(D6;B$1:F$2;2;1)*D6	=D6–E6
7	Иван	1	12000	=МАКС(0;C7–B7*B$3)	=ГПР(D7;B$1:F$2;2;1)*D7	=D7–E7
8	Олег	2	5000	=МАКС(0;C8–B8*B$3)	=ГПР(D8;B$1:F$2;2;1)*D8	=D8–E8
9	ВСЕГО		=СУММ(C6:C8)	=СУММ(D6:D8)	=СУММ(E6:E8)	=СУММ(F6:F8)

Рис. 5.20б

Пример 5.21. Прогрессивный налог. Построить таблицу вычисления годового прогрессивного подоходного налога с физических лиц. Расчеты налогов, выполненные ранее, не является корректными. Видим, что с суммы в 2000 он равен 240, а с 2001 – уже 300, т.е. наблюдается резкий скачек величины налога при росте дохода всего в одну единицу. На практике используется более сложная методика расчета налогов, когда новый уровень налогов относится только к соответствующему диапазону (прогрессивный налог). Разъясним ее на примере. Положим, что принята следующая налоговая сетка (область А1:С6). Налог в 12% исчисляется от суммы дохода до 10000, налог в 18% от суммы, находящейся в пределах от 10001 до 30000 и т.д. Однако 18% берется не со всей суммы, а только с той ее части, которая больше 10000. Аналогично налоги рассчитываются и в других диапазонах доходов. Для полного уяснения техники вычислений определим налог с дохода в 65000. Он состоит из следующих четырех компонент:

	A	B	C
1	Д о х о д		% налога
2	от:	до:
3	0	10 000	12%
4	10 001	30 000	18%
5	30 001	60 000	25%
6	60 001	и выше	35%
7	ДОХОДЫ
8	Ф.И.О.	Доход	Налог
9	Иван	5 000	600
10	Петр	20 000	3 000
11	Анна	50 000	2 300
12	Елена	65 000	14 050
13	Всего	140 000	19 950
		Рис.5.21	а

12% от суммы до 10000  0,12*10000=1200

18% от суммы 30000–10000=20000  0,18*20000=3600

25% от суммы 60000–30000=30000  0,25*30000=7500

35% от суммы 65000–60000=5000  0,35*5000 =1750

Сумма налога 14050

Или в виде формул:

Налог= ЕСЛИ(Доход <10, то 12%*Доход;

ЕСЛИ(Доход<30то 12%*10+18%*(Доход–10);

ЕСЛИ(Доход<60, то 12%*10+18%*20+25%*(Доход–30);

12%*10+18%*20+25%*30+35%(Доход–60)))).

Иллюстрирует технику вычислений рис. 5.21б (суммы в тысячах).

Рис. 5.21б

Перейдем к адресам для первого налогоплательщика в таблице:

B9=ЕСЛИ(B9<B$3;C$3*B9; ЕСЛИ(B9<B$4;C$3*B$3+C$4*(B9–B$3);

ЕСЛИ(B9<B$5;C$3*B$3+C$4*(B$4–B$3)+C$5*(B9–B$5);

C$3*B$3+C$4*(B$4–B$3)+C$5*(B$5–B$4)+C$6*(B9–B$5)))).

Замечание. С 2001 г. в России установлен единый налог в 13% для физических лиц независимо от доходов. Однако сама задача (но только не для налогов) остается актуальной, поскольку прогрессивная шкала расчетов используется во многих других случаях и не только в финансовых расчетах.

	A	B	C	D	E	F	G	H	I
1	Доход до	20000:	12%
2	Свыше	20000:	20%
3		Динамическое исчисление налогов
4	Имя	Сводный		Январь		Февраль		Март
5		Доход	Налог	Доход	Налог	Доход	Налог	Доход	Налог
6	Иван	24000	4800	8000	960	9000	1080	7000	2760
7	Петр	1800	216	800	96	1000	120
8	Анна	4000	480	400	48	600	72	3000	360
9	Елена	14300	1716	300	36	8000	960	6000	720
10	Всего	44100	7212	9500	1140	18600	2232	16000	3840
				Рис.	5.22а

Пример 5.22. Динамическое исчисление налогов. Определение налогов в конце года ставит задачу выплаты работником сразу большой суммы, возможно даже значительно большей, чем зарплата за последний месяц/месяцы. Кроме того, в случае увольнения работника в конце года вообще проблематично получить с него этот самый налог. В виду сказанного, на предприятиях ежемесячный налог обычно исчисляется от нарастающей суммы дохода с вычетом уплаченных ранее налогов. На рисунке изображена таблица расчетов налогов к марту месяцу. В рассматриваемом примере для упрощения выкладок налоговая сетка имеет всего две строчки – для дохода до и свыше 20000. Для упрощения же считаем, что налог со всей суммы от 20000 составляет именно 20%. Наша задача – научиться определять налог в каждом из 12 месяцев, таким образом, чтобы учесть как тарифную сетку, так и уже уплаченные в предыдущих месяцах налоги. Для этого следует выполнить вычисления:

налог_в_текущем_месяце=

сумма_всех_доходов_к_дате_расчета*процент_налога–сумма_ранее_уплаченных_налогов.

Или конкретнее:

налог=сумма_всех_клеток,_имеющих_в_заголовке_слово_Доход*размер_совокупного_налога

–сумма_всех_клеток,_имеющих_в_заголовке_слово_Налог.

Технику вычислений налога для первого сотрудника (Ивана) в марте иллюстрирует таблица на рис. 5.22б.

Месяц	Доход	Полный налог за истекший период	Внесенный ранее налог	Налог теку- щего месяца
Январь	8000	12% от 8000=960	0	960
Февраль	9000	12% от 17000=2040	960	1 Рис. 5.22б 080
Март	7000	20% от 24000=4800	2400	2760

Ниже показаны клеточные формулы налога для первого сотрудника в январе и феврале.

E6=СУММЕСЛИ($D$5:D$5;"Доход";$D6:D6)*ЕСЛИ(СУММЕСЛИ($D$5:D$5;"Доход";$D6:D6)<=$B$1;

$C$1;$C$2)–СУММЕСЛИ($D$5:D$5;"Налог";$D6:D6),

G6=СУММЕСЛИ($D$5:F$5;"Доход";$D6:F6)*ЕСЛИ(СУММЕСЛИ($D$5:F$5;"Доход";$D6:F6)<=$B$1;

$C$1;$C$2)–СУММЕСЛИ($D$5:F$5;"Налог";$D6:F6).

Формула для G6 получена простым копированием в нее клетки Е6.

Здесь сумма всех доходов СУММЕСЛИ($D$5:D$5;"Доход";$D6:D6) умножается на процент налога $C$1, если она меньше $B$1 (меньше 20000), или на $C$2, если больше. Затем из результата вычитается сумма уже удержанных ранее налогов СУММЕСЛИ($D$5:D$5;"Налог"; $D6:D6).

Кроме того, нарастающим итогом вычисляются суммы доходов и налогов:

Сводный доход: B6=СУММЕСЛИ($D$5:$Y$5;"Доход";D6:Y6).

Сводный налог: C6=СУММЕСЛИ($D$5:$Y$5;"Налог";D6:Y6).

Эти сводные данные мы, против обыкновения, разместили не в конце (т.е. в правой части) таблицы, а в ее начале, что удобнее для пользователя, поскольку ему не придется перелистывать громоздкую таблицу по горизонтали, чтобы их увидеть (в декабре таблица достигнет столбца Y).

Пример 5.23. Расчет стипендии. Создать таблицу начисления стипендии студентам ВУЗа и получения сводных данных о результатах сессии. Пусть в сессию студентами сдавались три экзамена и два зачета. В качестве результата экзамена вводится его оценка (кроме двойки). Сданный зачет отмечается значком “+”. Стипендия назначается всем студентам, полностью сдавшим сессию, в размере, определяемом средним баллом. Для выполнения расчетов имеется таблица коэффициентов, связывающая ее размер с величиной минимальной зарплаты (область K4:L8). Конечно, студенты, не сдавшие сессию, стипендии не получают и, кроме того, в столбце Задолжники они помечаются словом ”1зд” (если задолженность одна), или словом “отч” (более одной задолженности), как планируемые к отчислению из института за академическую неуспеваемость.

Рассмотрим, какие формулы необходимы для первого студента в списке (Петра). Средний балл (G4) определяется как сумма всех баллов, полученных на экзаменах, деленная на их число ((B4+C4+D4)/3). Однако, если студент не сдал какой-либо из экзаменов или зачетов, т.е.

История<3 ИЛИ Физика<3 ИЛИ Химия<3 ИЛИ Правозачет ИЛИ Этиказачет,

средний балл принимается равным 0. Таким образом, критерий несдачи сессии Петром будет таков ИЛИ(В4<3;C4<3;D4<3;E4<>"+";F4<>"+"). Его можно несколько упростить, если воспользоваться косвенным признаком, а именно тем фактом, что для несданных предметов клетки оценок остаются пустыми. Тогда для экзаменов произведение всех оценок равно нулю (B4*C4*D4=0), а для зачетов последовательность отметок не равна "++" (т.е. E4&F4<>"++"). Для формирования анализируемой строки все клетки, содержащие зачеты, сцепляются в одно слово (E4&F4). Окончательно, формула для Н4 будет иметь вид

G4=ЕСЛИ(ИЛИ(B4*C4*D4=0;E4&F4<>"++");0;(B4+C4+D4)/3).

В качестве признака наличия академических задолженностей можно использовать и еще более простой критерий – длина строки (ДЛСТР()), образованной сцеплением оценок, меньше числа предметов

G4=ЕСЛИ(ДЛСТР(B4&C4&D4&E4&F4)<5;0;(B4+C4+D4)/3).

	A	B	C	D	E	F	G	H	I	J	K	L
1		СТИПЕНДИЯ									Мин.	зарп.
2	Студент	Экзамены			Зачеты		Ср. балл	Стипендия	Задолжн.			100р
3		История	Физика	Химия	Право	Этика					Ср. балл	К оэфф.
4	Петр	5	5	5	+	+	5,0	200р			3	1
5	Иван	4	5	5	+	+	4,7	180р			3,5	1,1
6	Саша	4	4	4	+	+	4,0	150р			4	1,5
7	Олег	3	3	5	+	+	3,7	110р			4,5	1,8
8	Вера	3	3	3	+	+	3,0	100р			5	2
9	Игорь	4	5		+	+			1зд
10	Лена	4			+	+			отч
11	Ср.балл	3,9	4,2	4,4				Сумма

12Сдало76577740рРис. 5.23аВеличина начисляемой стипендии (H4) определяется с помощью функции вертикального поиска значения G4 в области K4:L8. Найденный коэффициент умножается на величину минимальной зарплаты L2. Таким образом H4=ЕСЛИ(G4=0;0;ВПР(G4;K$4:L$8;2;1)*L$2). Поскольку в таблице коэффициентов отсутствует строка, где средний балл равен нулю, этот факт пришлось учитывать непосредственно в формуле H4.

Неуспевающие студенты выявляются следующим образом. Сначала определяются студенты, имеющие менее четырех оценок (к отчислению), затем – все остальные, не сдавшие сессию (т.е. с одной задолженностью).

I4=ЕСЛИ(ДЛСТР(B4&C4&D4&E4&F4)<4;"отч";ЕСЛИ(H4=0;" 1зд ";"")).

Кроме собственно стипендии в таблице вычисляются некоторые простые сводные характеристики: средний балл по всем экзаменам для студентов, имеющих оценки (B11=СРЗНАЧ(B4:B10) и т.д.), число студентов, получивших положительные оценки по каждому предмету (B12=СЧЁТ(B4:B10)), число студентов, получивших зачет по каждому из предметов (E11=СЧЁТЗ(B4:B10)), общую сумму всех назначенных стипендий (H12=СУММ(H4: H10)). По итогам сессии обычно требуется сформировать и более сложные показатели, например такие (рис. 5.23б). Рассмотрим как они получаются.

Число всех студентов успешно сдавших сессию: D14=СЧЁТЕСЛИ(G$4:G10;">0").

Число студентов сдавших сессию только на отлично (отличников): D15=СЧЁТЕСЛИ(G$4:G10;5).

Количество студентов сдавших сессию без троек (хорошистов):

D16 {=СЧЁТ(ЕСЛИ(B$4:B10>3;ЕСЛИ(C$4:C10>3;ЕСЛИ(D$4:D10>3;ЕСЛИ(G$4:G10>0;ЕСЛИ(G$4:G10<5;1))))))}.

Здесь подсчитываются только студенты не имевшие троек на всех экзаменах и средним баллом больше нуля и меньше пяти (последнее позволяет исключить из подсчета отличников, поскольку только для них средний балл =5). Такая формула может быть только формулой для массивов, т.е. ее ввод завершается нажатием клавиш Ctrl+Shift+Enter (выражение обрамляется фигурными скобками). Если воспользоваться тем фактом, что результатом операции сравнения будет число 1 или 0 (отношение истинно/ложно), формулу можно упростить следующим образом

D16 {=СЧЁТ(ЕСЛИ((B4:B10>3)*(C4:C10>3)*(D4:D10>3)*(G4:G10>0)*(G4:G10<5);1))}.

Количество студентов сдавших сессию с тройками (троечников):

D17 {=СЧЁТ(ЕСЛИ((G$4:G10>0)*((B$4:B10=3)+(C$4:C10=3)+(D$4:D10=3));1))}.

Здесь подсчитываются студенты, имеющие средний балл больше нуля и хотя бы одну тройку на экзамене.

Число студентов не сдавших сессию, т.е. средний балл которых равен нулю (двоечники): D18=СЧЁТЕСЛИ(G$4:G10;0).

Количество студентов, подготавливаемых к отчислению (имеющих минимум две задолженности):

D19 {=СЧЁТ(ЕСЛИ(((B$4:B10=0)+(C$4:C10=0)+(D$4:D10=0)+(E$4:E10<>"+")+(F$4:F10<>"+"))>1;1))}.

Подсчитываются студенты, имеющие больше одного (>1) “хвоста”.

Последний вычисляемый параметр – средний балл студентов, сдавших сессию (для них средний балл >0)

D20 {=СРЗНАЧ(ЕСЛИ(G$4:G10>0;G$4:G10))}.

Пример 5.24. Оплата труда в торговле. Создать таблицу назначения еженедельных премий продавцам-менеджерам фирмы в зависимости от суммы (в тыс. руб.) проданного ими товара. Премиальный фонд (20% от общей выручки – клетка E3) назначается только менеджерам, занявшим по сумме продаж первые три места. В абсолютном исчислении эта сумма равна E4=E3*B14 (здесь 20% от 73 =14,6 тыс. руб.). Эта сумма делится между участниками в следующей пропорции: с коэффициентом 1 – за 1 место, с коэффициентом 0,7 – за второе, с коэффициентом 0,4 – за третье. По очевидным причинам таких людей может оказаться больше трех, если некоторые из “призеров” имели одинаковую выручку. В таблице должны фигурировать: имя продавца, процент выручки данного работника от общей суммы, призовое (если есть) место продавца, индивидуальный коэффициент премирования и премия (если есть). Сначала в таблице вычисляется общая сумма выручки B14=СУММ( B8:B13). Затем для каждого продавца находится процент его личной выручки C8=B8/B$14. Теперь следует выявить призовые места работников, используя функцию РАНГ( ): D8=РАНГ(B8;B$8:B$13;0). В столбце Коэффициенты отражаются индивидуальные коэффициенты премирования в зависимости от занятого места. Функция ВЫБОР( ) извлекает из таблицы коэффициентов премирования нужные значения.

E8=ВЫБОР(ЕСЛИ(D8<=3;D8;4);B$3;B$4;B$5;0).

Если занятое место имеет значения 1, 2, 3 (т.е. 3), его коэффициент разыскивается в группе ячеек B3, B4, B5. Если нет, искомое значение принимается равным четырем. Этому значению в группе извлечения соответствует цифра ноль (последний аргумент в функции).

Собственно премия определяется очевидным образом

премия=премиальный_фонд/сумма_коэффициентов*индивидуальный_коэффициент. Или F8=E$4/E$14*E8.

Как видим, сумма премий (F14) в точности равна премиальному фонду (E3), т.е. расчеты выполнены верно.

К оформлению.

1. Удобно, если имена лучших работников будут выделены. Например, занявшие первое место – красным фоном, второе место – синим, третье – зеленым. Для этого выполним условное форматирование блока А8:А13 следующего вида:

Условие 1 значение равно 1  – установить красный фон

Условие 2  значение равно 2  – установить синий фон

Условие 3  значение равно 3  – установить зеленый фон

2. Заметим, что столбец индивидуальных коэффициентов работников нужен только по техническим причинам (ради вычисления суммы всех коэффициентов) и по завершении построения таблицы его можно скрыть, оставив лишь значимые данные. Такой облик таблицы не отвлекает пользователя от восприятия важной информации и в то же время не ограничивает его в действиях – он может редактировать, удалять и создавать новые строки, не вникая больше в суть формул в скрытых столбцах.

Следует отметить, что при рассмотренном способе определения призовых мест может оказаться, например, 4 первых места и ни одного второго или третьего (если четыре человека имели одну и ту же максимальную выручку) или, как в нашем случае, 2 первых и 2 третьих места и ни одного второго (два человека имели одинаковую максимальную выручку и еще два – одинаковую выручку поменьше) и т.п. Если такой механизм выявления призеров вас устраивает, все в порядке. Если же вы хотите, чтобы в таблице обязательно присутствовали все три первых места без пропусков, то придется поступить более сложным способом. На рис. 5.24б приведен фрагмент такой таблицы. Для экономии места строки с первой по шестую опущены (они идентичны рис. 5.24а). Здесь при определении призового места нами введены три дополнительных столбца D, E, F. В столбце D выявляем лиц, занявших 1 место. Они отмечаются текстом вида “1м”. Для остальных работников отображается их выручка

	A	B	C	D	E	F
1		Премия продавцам:
2	К-ты премирования			Премиальный фонд
3	за 1 место	1		Процент:	20%
4	за 2 место	0,7		Сумма:	14,6т
5	за 3 место	0,4
6	П Р О Д А Ж И
7	Продавец	Выручка	Процент	Место	Коэфф.	Премия
8	Петр	12т	16,4%	3	0,4	2,1т
9	Иван	9т	12,3%	5
10	Елена	12т	16,4%	3	0,4	2,1т
11	Саша	20т	27,4%	1	1	5,2т
12	Федор			6
13	Толя	20т	27,4%	1	1	5,2т
14	ВСЕГО	73т	100,0%		2,8	14,6т
			Рис.	5.24а

=ЕСЛИ(максимальная выручка в магазине=выручка данного работника, то выводим “1м”, иначе сама выручка)

или D10=ЕСЛИ(МАКС(B$10:B$15)=B10;"1м";B10).

В столбце E аналогичным образом выявляем лиц, занявших 1 и 2 места, а F – 1-3 места. Однако в качестве анализируемой области используем не исходный столбец Выручка, а предшествующий столбец, содержащий не только значения выручки, то текстовые строки, которые теперь замещают числовые значения

E10=ЕСЛИ(МАКС(D$10:D$15)=D10;"2м";D10)

F10=ЕСЛИ(МАКС(E$10:E$15)=E10;"3м";E10).

Функция МАКС( ) находит максимальное число в области D10:D15. Имеющиеся здесь текстовые значения вида “1м” воспринимаются ею как нули. Теперь мы превратим текстовые значения в числовые (“1м” – в цифру 1, “2м” – в 2, “3м” – в 3). Это можно сделать с помощью функции ЕСЛИ( )

G10=ЕСЛИ(F10="1м";1;

ЕСЛИ(F10="2м";2;ЕСЛИ(F10="3м";3;0))).

	A	B	C	D	E	F	G	H	I
					. . .
7	Продавец	Выручка		1м	1-2м	1-3м	Место	Коэфф.	Премия
8	Петр	12		12	2м	2м	2	0,7	2,7
9	Иван	9		9	9	3м	3	0,4	1,5
10	Елена	12		12	2м	2м	2	0,7	2,7
11	Саша	20		1м	1м	1м	1	1	3,8
12	Федор
13	Толя	20		1м	1м	1м	1	1	3,8
14	ВСЕГО	73						3,8	14,6
					Рис.6	.24б

Здесь, если место не призовое, результатом будет 0. Возможно и более короткое решение путем непосредственного преобразования первого символа в слове на число G10=ЗНАЧЕН(ЛЕВСИМВ(F10;1)).

Далее находим, соответствующий занятому месту, коэффициент премирования

H10=ВЫБОР(ЕСЛИ(G10<1;4;G10);B$3;B$4;B$5;0).

Если занятое место <1 (в нашем случае 0), коэффициент принимается равным нулю.

Видим, что сумма премиальных выплат совпадает с выделенным фондом, т.е. расчеты произведены правильно, однако сами премии оказались иными, нежели на рис. 5.24а.

Далее технические столбцы D, E, F можно скрыть.

Пример 5.25. Расчет размеров помощи. Создать таблицу расчетов по выделению материальной помощи работникам предприятия. Положим, она назначается по двум причинам:

1. При наличии более 2-х и более детей – в размере одной минимальной зарплаты на каждого ребенка.

2. Инвалидам и участникам войны (УчВ) в возрасте свыше 60-и лет – в размере двух минимальных зарплат.

Для Иванова это:

1. ЕСЛИ(C6>2;C6*F$1;0).

2. ЕСЛИ(И(ГОД(B$1)–B6>60;ИЛИ(D6="И";E6="У"));2*F$1;0).

В любом случае размер помощи не может превышать собственную зарплату работника (=МИН(F6;<расчетная помощь>)). Таким образом, полная формула будет выглядеть так

G5=МИН(F6;(ЕСЛИ(C6>2;C6*F$1)+ЕСЛИ(И(ГОД(B$1)–B6>60;ИЛИ(D6="И";E6="У"));2*F$1))).

По вертикали определяется средний возраст работников предприятия

=число_лет_текущей_даты – средний_возраст_работников или B9=ГОД(B$1)–СРЗНАЧ(B6:B8).

	A	B	C	D	E	F	G	H
1	Дата:	Ноя.99		Миним.	зарп.	80
2
3	НАЗНАЧЕНИЕ ПОМОЩИ
4	ФИО	Год рожд.	Детей	Л ь г о т ы		Зарп- лата	По- мощь	Всего
5				Инвалид	УчВ
6	Иванов	1940	3	И		600	240	840
7	Петров	1970	2			500	0	500
8	Кулик	1920	5	И	У	550	550	1100
9	Итого	56,7лет	10	2	1	1650	790	2440
				Рис. 5.25

Для этой ячейки назначен пользовательский формат вида: 0,0"лет". Кроме того, вычисляются число инвалидов (D9=СЧЁТ­ЕСЛИ(D6:D8;"И") и участников войны (E9=СЧЁТЕСЛИ(E6:E8;"У"). Если бы нам понадобилось вычислить число лиц имеющих обе льготы (т.е. инвалидность и участие в войне), то пришлось бы прибегнуть к формулам, работающим с массивами: {=СЧЁТ(ЕСЛИ(D6:D8= "И";ЕСЛИ(E6:E8="У";1)))} или проще {=СЧЁТ( ЕСЛИ((D6:D8="И")* (E6:E8="У");1))}.

Замечание. Здесь средний возраст определен весьма приблизительно, поскольку для работников отсутствуют сведения о месяце и дне рождения, т.е. как бы считается, что они родились 1 января. Для нахождения статистических данных, вроде среднего возраста всех членов коллектива, это несущественно, но при вычислении, например, трудового стажа, влияющего на оплату труда, так поступать нельзя. К этому вопросу мы вернемся позже.

Пример 5.26. Оплата проката автомобилей. Создать таблицу расчетов с клиентами за наем автомобилей, цена часа проката которых известна. В момент взятия в прокат автомобиля работник пункта проката выставляет текущие и ожидаемые дату и время возврата (столбцы Взято с и Оплачено по). Для столбцов С, D и G назначен пользовательский формат даты вида Д.МММ чч:мм. Исходя из стоимости часа проката, в таблице вычисляются время проката в часах и его стоимость. Для первой строки E6=(D6–C6)*24 и F6=B6*E6. В момент возврата автомобиля оператор выставляет время возврата (столбец G). В колонке Н и I вычисляется разница в часах и деньгах между оплаченной и фактической датами возврата автомобиля Н6=(G6–D6)*24 и I6=B6*H6. Если клиент вернул его раньше оплаченного времени, ему возвращается часть денег (коэффициент возврата находится в клетке C1). Если позже – с него берется недостающая сумма с коэффициентом доплаты (находится в С2) за задержку автомобиля в прокате J6=ЕСЛИ(I6>0;I6*C$2;I6*C$1). Так, за прокат автомобиля ВАЗ клиенту будут возвращены деньги.

	A	B	C	D	E	F
1	К-т возв	рата	0,50
2	К-т допл	аты	1,30
3				П Р О К А Т	А В Т	О М О	Б И Л Е Й
4	Тип	Цена	Взято	Оплачено	Опла	чено	Дата	Раз	ница	Доплата
5	авто	часа	с:	по:	часов	сумма	возврата	часы	сумма	/возврат
6	Волга	110	2.Ноя 10:00	12.Ноя 00:00	230,0	25300	18.Ноя 05:00	149	16390	21307
7	БМВ	300	13.Ноя 01:30	21.Ноя 10:00	200,5	60150	21.Ноя 10:00	0	0	0
8	Рено	200	4.Ноя 09:06	14.Ноя 00:00	230,9	46180	16.Ноя 08:00	56	11200	14560
9	Ауди	250	1.Ноя 01:00	5.Ноя 10:00	105,0	26250	7.Ноя 00:30	38,5	9625	1 Рис. 5.26 2512,5
10	ВАЗ	100	6.Ноя 06:30	19.Ноя 12:00	317,5	31750	14.Ноя 00:00	–132	–13200	–6600

Пример 5.27. Зарплата с учетом разряда и трудового стажа. Создать таблицу расчета выплат заработка по результатам месяца в зависимости от разряда и стажа работников. Для этого имеется тарифная сетка, содержащая коэффициенты премирования сотрудника в зависимости от его разряда и стажа работы на производстве (в левой верхней части листа на рис. 5.27б). Стаж изображается в форме цифры стажа и слова “лет” (например “10 лет”) с помощью формата вида: 0” лет”, а разряд (например “3 разр.”)– с помощью формата 0” разр.” О каждом сотруднике известны: дата поступления его на предприятие (Дп), разряд, зарплата. На основе этих данных необходимо определить его премию (доплату за стаж и разряд) на произвольно заданный день расчета (Др). Кроме того, следует найти средний трудовой стаж всех работников.

Задача определения числа прошедших лет и/или месяцев является очень актуальной. Во многих случаях стаж работы влияет на оплату труда (например, выслуга лет у военнослужащих, размер пенсии и т.п.). Ее решение может быть различным в зависимости от целей расчета. Если требуется найти, например, средний стаж работников предприятия, то достаточно просуммировать стаж (в днях) каждого из них и поделить на 364 и число работников. Не так в случае определения стажа отдельного работника, если это влияет на оплату труда. Если поступить аналогичным образом, может оказаться, что будет получена неточная цифра, ведь число дней в году может составлять и 365. Кроме того, перерасчет зарплаты производится не немедленно по достижении нужной даты, а начиная только со следующего месяца – по прошествии установленного числа полных месяцев стажа. Пусть, например, сотрудник зачислен на работу 12.6.94 и через пять лет (т.е. после 12.6.99) ему положена прибавка зарплаты. По существующему законодательству она последует только в следующем месяце – в июле 1999 г.

	11.97	12.97	1.98	2.98	3.98	4.98	5.98	6.98	7.98	8.98	9.98	10.98	11.98	12.98	1.99	2.99
		1	2	3	4	5	6	7	8	9	10	11	12	13

Теперь получим формулы расчета искомого промежутка времени. Определим его как разность между числом месяцев, прошедших от 1.1.1900 г. (от начала отсчета всех дат в Excel) до начала месяца Дп, и числом месяцев от 1.1.1900 г. до начала месяца Др и вычтем отсюда еще один месяц (месяц в котором находится Дп).

Выполним сначала эти расчеты применительно к нашим данным.

1. Число полных месяцев от 1.1.1900 до месяца Дп:

Год поступления*12 + Месяц поступления – 1.

В нашем случае это

ГОД(15.11.1997)*12+МЕСЯЦ(15.11.1997)-1=1997*12+11-1=23974 месяца.

2. Число полных месяцев от 1.1.1900 до месяца Др, исключая один месяц, в котором находится Дп:

Год расчета*12+ Месяц расчета –1–1 или

ГОД(25.1.1999)*12+МЕСЯЦ(25.1.1999)-1-1=1999*12+1-1-1=23987 месяцев.

3. Число полных месяцев от Дп до Др:

Месяцев до даты расчета – Месяцев до даты поступления или 23987–23974=13 месяцев.

Таким образом, можем записать

(ГОД(Др)*12+МЕСЯЦ(Др)–1–1)–(ГОД(Дп)*12+МЕСЯЦ(Дп)–1)=

ГОД(Др)*12+МЕСЯЦ(Др)–1–ГОД(Дп)*12–МЕСЯЦ(Дп)=

12*(ГОД(Др)–ГОД(Дп))+МЕСЯЦ(Др)–МЕСЯЦ(Дп)–1.

Если подсчет стажа ведется в годах, полученный результат нужно поделить на 12. Воспользуемся полученным выше выражением. Так, для первого работника стаж в годах (Е9) составит

E9=(12*(ГОД(G$2)–ГОД(B9))+МЕСЯЦ(G$2)–МЕСЯЦ(B9)–1)/12.

Теперь найдем коэффициент премирования в таблице тарифных ставок. Этот коэффициент находится на пересечении колонки с соответствующим разрядом (функция ПОИСКПОЗ(C9;A$1:F$1;0)) и стажем (функция ПОИСКПОЗ(E9;A$1:A$6;1)). Адрес клетки пересечения определяется функцией ИНДЕКС(A$1:F$6; номер_строки; номер_ столбца). Или окончательно

F9=ИНДЕКС(A$1:F$6;ПОИСКПОЗ(E9;

A$1:A$6;1);ПОИСКПОЗ(C9;A$1:F$1;0).

Замечание. Здесь в качестве блока поиска определена целиком вся тарифная сетка, включая ячейку А1. Это в некоторых случаях может вызвать неверный результат поскольку ее содержимое в таком случае также попадает в область поиске. Если функция ПОИСКПОЗ(…) посчитает значение клетки A1 соответствующим критерию поиска, результат может быть извлечен совершенно из другого места таблицы тарифов, либо последует сообщение об ошибке. Если такая опасность существует, можно изменить функцию таким образом, чтобы исключить из обработки ячейку А1

=ИНДЕКС(B$2:F$6;ПОИСКПОЗ(E9;A$2:A$6;1);ПОИСКПОЗ(C9;B$1:F$1;0)).

	A	B	C	D	E	F	G
1	Разряд /стаж	1 разр.	2 разр.	3 разр.	4 разр.	5 разр.	Дата расчета:
2	0 лет	1,0	1,1	1,2	1,3	1,4	20.09.99
3	5 лет	1,2	1,3	1,4	1,5	1,6
4	10 лет	1,4	1,5	1,6	1,7	1,8
5	20 лет	1,6	1,7	1,8	1,9	2,0
6	30 лет	1,8	1,9	2,0	2,1	2,2
7		ЗАРПЛАТА
8	Имя	Дата поступ.	Разр.	Зарп.	Стаж (лет)	Коэфф.	ВСЕГО
9	Петр	20.06.99	5	100	0,2	1,4	140
10	Иван	12.08.94	4	200	5,0	1,5	300
11	Олег	20.10.65	4	180	33,8	2,1	378
12	Сергей	01.04.70	2	500	29,3	1,7	850
13	Итого	ср.стаж:17		980			1668
			Рис.	5.27б

Средний стаж вычисляется как среднее арифметическое дат поступления, отнятое из даты расчета. Для перевода дней в годы результат делится на число дней в году (364) и округляется до целого, поскольку здесь не требуется высокой точности

B12=ОКРУГЛ((G$2–

СРЗНАЧ(B9:B12))/364;0).

Формат ячейки: “ср.стаж:”#.

Выплаты с учетом коэффициента (колонка Всего) определятся формулой вида G9= F9*D9. Внизу таблицы обычные формулы вертикаль­ного суммирования – D13=СУММ(D9:D12), G13=СУММ(G9:G12).

Пример 5.28. Переоценка основных фондов предприятия. Обо всех объектах, составляющих основные фонды, известны: год приобретения; цена (в тыс. руб.), по которой он был закуплен; срок амортизации (число лет, на которое рассчитано устройство до полного износа и списания). Нам нужно создать таблицу ежегодной переоценки (на конец 1999 года) стоимости фондов, которая зависит от двух факторов.

	A	B	C	D	E	F	G	H
1	Текущий	год:	1999
2			Инфляция
3	1992	1993	1994	1995	1996	1997	1998	1999
4	2200%	1200%	700%	150%	30%	16%	50%	30%
5			Переоценка
6	Фонды	Куплено		Срок аморт.	№	Новая цена
7		Год	Цена
8	Станок	1994	10	30	3	490
9	Кран	1996	20	20	5	50
10	Стенд	1982	30	8	1	0
11	Копир	1991	10	9	1	19539
12	Факс	1999	4	4	8	5
13	ВСЕГО					20084
			Рис.	5.28

1. Увеличение стоимости под влиянием инфляции. Сводка об инфляции (процентах снижения покупательной способности рубля) с 1992г. отображена в строках 3 и 4. Считаем, что до 1992г. инфляции не было. Деноминация рублей учитывается в исходной цене объектов. Цена предметов, купленных на “старые” деньги, уменьшается в 1000 раз, остальные цены остаются без изменения.