Обработка событий
Архитектуру программы, выполняющейся в операционной системе Windows, достаточно сложно нарисовать в виде визуальной схемы. Например, пусть программа только что начала работать. На экране показывается главное меню программы, и пользователь нажимает на кнопку мыши. Нажатие на кнопку мыши является событием, начинает работать определенный объект. Пользователь мог бы не нажимать кнопку мыши, и тогда работа программы пошла бы по другому сценарию. То есть ситуация типа: может быть, а может и не быть.
В вероятностной структуре (это структура, в которой не все маршруты, трассы кодов жестко закреплены; в этой архитектуре элементы программ могут включаться при возникновении некоторого события, которое может произойти, а может и не произойти) сильно увеличивается количество возможных состояний и сценариев работы программы. Здесь пользователь определяет порядок работы программы.
Приложения Delphi используют управляемые событиями методы для организации взаимодействия между программой и пользователем. Большую часть кода, которую вы будете писать в Delphi, будет инициироваться событиями. В принципе событием может быть изменение любой величины. Происхождение события заставляет работать определенный объект, при этом объект получает заранее определенные параметры для своей настройки на работу. В Delphi процедура, инициируемая событием, называется обработчиком события.
События делятся на три основные категории: события мыши, события клавиатуры и системные события.
События мыши
Для формы событие OnClick возникает в том случае, если пользователь нажимает левую кнопку мыши в то время, когда курсор мыши находится на поле формы.
Упражнение 1. Напишите приложение, которое при нажатии левой кнопки мыши перекрашивает форму в синий цвет.
Решение
Создайте обработчик события OnClick: выберите страницу Events инспектора объектов и выполните двойной щелчок мышью в правой колонке, напротив события OnClick. На переднем плане появится окно редактирования модуля с помещенной сразу в нужное место модуля заготовкой обработчика события OnClick.
В обработчике события указан параметр Sender, в котором хранится имя объекта, породившего данное событие (в примере Sender будет содержать ссылку на объект MainF – форму).
Для изменения цвета формы в обработчике события OnClick напишем следующий оператор:
procedure TMainF.FormClick(Sender: TObject);
begin
MainF.Color := clBlue (*)
end;
Поясним оператор (*). MainF – это название объекта формы. Color – это свойство формы. Обращение к свойствам объекта происходит так же, как и в структуре данных записи, через точку.
Запустите приложение. Щелкните левой кнопкой мыши по форме. Убедитесь, что цвет формы стал синим. При повторном щелчке опять возникнет событие OnClick форма снова становится синей, но пользователю это не видно.
Упражнение 2. Напишите приложение, в котором при каждом щелчке левой кнопкой мыши произвольным образом изменяется цвет формы.
Решение
Модифицируем код модуля Main.pas.
Для получения различных цветов для формы воспользуемся функцией RGB. Функция RGB(Red, Green, Blue) принимает три параметра - уровни интенсивности красного, зеленого и синего цвета, соответственно, и возвращает цвет Win32 как целое значение. Для каждого уровня интенсивности существует 256 возможных значений. Например, RGB(255, 0, 0) возвращает цветовое значение для красного цвета, а RGB(255, 0, 255) – сиреневого цвета.
Итак, щелчок левой кнопкой мыши по форме порождает событие OnClick формы, т.е. приводит к обращению к процедуре TMainF.FormClick, в результате чего выполняется оператор (*) – изменение цвета формы на синий. Изменим оператор (*) в соответствии с формулировкой задачи:
procedure TMainF.FormClick(Sender: TObject);
begin
Color := RGB(Random(256), Random(256), Random(256)); (**)
end;
Сравните правые части операторов (*) и (**). Оператор (*) изменяет цвет конкретного объекта типа TMainF (под именем MainF). Оператор (**) позволяет изменить цвет любого объекта типа TMainF, следовательно, этот оператор более общий, и далее будем использовать его при обращении к форме.
Запустите приложение. Убедитесь, что после каждого щелчка по форме левой кнопкой цвет изменяет произвольным образом.
Упражнение 3. Напишите приложение, в котором при нажатии на левую кнопку мыши происходит смена цвета с голубого на синий, и, наоборот, с синего на голубой.
Решение
При щелчке по левой кнопке мыши происходит событие OnClick. В соответствии с условием задачи в обработчике события OnClick формы необходимо проанализировать свойство Color формы: если его значение соответствует синему, то изменить его на голубой (clAqua), иначе присвоить значение clBlue. На языке Object Pascal это записывается так:
procedure TMainF.FormClick(Sender: TObject);
begin
if Color=clBlue then Color:=clAqua else Color:=clBlue;
end;
Сохраните приложение, запустите его. Проверьте выполнение условия задачи.
Событие OnDblClick происходит, если пользователь выполняет двойной щелчок левой кнопки мыши.
Упражнение 4. Напишите приложение, в котором при двойном щелчке левой кнопкой мыши изменяется вид курсора.
Решение
Каждое значение свойства Cursor имеет свой числовой эквивалент в пределах от –21 (crHandPoint) до 0 (crDefault). При каждом двойном щелчке левой кнопкой мыши значение свойства Cursor будем увеличивать на единицу, при достижении значения 0 – восстановим значение -21. Введите в обработчик события формы OnDblClick следующий оператор:
procedure TMainF.FormDblClick(Sender: TObject);
begin
if Cursor=0 then Cursor:=-21 else Cursor:=Cursor+1;
end;
Сохраните проект и запустите его. Объясните, почему при каждом двойном щелчке левой кнопкой мыши сначала изменяется цвет формы, а затем – вид курсора.
Событие OnMouseDown возникает, если пользователь нажимает на правую, левую или среднюю кнопку мыши. Заголовок обработчика этого события имеет вид:
procedure TMainF.FormMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
Событие OnMouseUp происходит, если пользователь освобождает кнопку мыши, которая была нажата. Заголовок обработчика этого события имеет вид:
procedure TMainF.FormMouseUp(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
Событие OnMouseMove происходит, если пользователь перемещает указатель мыши. Заголовок обработчика этого события имеет вид:
procedure TMainF.FormMouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
В параметре Button обработчики этих событий получают одно из значений mbLeft, mbRight или mbMiddle, в зависимости от того, какая кнопка мыши была нажата – левая, правая или средняя.
Параметр Shift указывает состояние клавиш Alt, Ctrl, Shift и кнопок мыши. Тип TShiftState описан так:
TShiftState = set of (ssShift, ssAlt, ssCtrl, ssLeft, ssRight, ssMiddle, ssDouble);
Значения ssShift, ssAlt, ssCtrl принадлежат множеству Shift, если клавиши Shift, Alt, Ctrl, соответственно, были нажаты; ssLeft, ssMiddle, ssRight – если нажаты левая, средняя или правая кнопки мыши; ssDouble – если произошел двойной щелчок.
В параметрах X и Y процедура получает координаты указателя мыши, выраженные в пикселях относительно формы.
Упражнение 5. Напишите приложение, позволяющее рисовать отрезки на форме.
Решение
Закройте предыдущий проект, выполнив команду Close All меню File. Создайте новое приложение, выполнив последовательность команд: File/ New Application. Сохраните новое приложение в папке Exercise2. Файл модуля – под именем Main.pas, файл проекта – Exercise2.dpr.
Измените свойства формы следующим образом:
-
Name
MainF
Caption
Отрезки
Все графические операции в Delphi выполняются с использованием свойства Canvas. Это свойство объектного типа. Класс TCanvas – сердцевина графической подсистемы Delphi. Он объединяет в себе контекст конкретного устройства GDI (интерфейс графических устройств) и «рабочие инструменты» (перо, кисть, шрифт, набор функций по рисованию типовых геометрических фигур). В процессе конструирования приложения свойство Canvas недоступно в окне инспектора объектов, оно доступно только во время выполнения приложения.
Чтобы нарисовать на форме пунктирную линию красного цвета от точки с координатами (10,10) до точки (300,300), создайте обработчик события формы Click и введите следующие операторы:
with Canvas do begin
Pen.Color:=ClRed;
Pen.Style:=PsDash;
MoveTo(10,10);
LineTo(300,300);
end;
Поясним код обработчика события. С помощью свойства Pen можно установить параметры изображения линии, такие как цвет (Сolor), тип (Style), толщину (Width).
Метод MoveTo(x,y) перемещает графический курсор в точку с координатами (x,y).
Метод LineTo(x,y) рисует отрезок от текущего положения графического курсора до точки с координатами (x,y).
Сохраните проект. Убедитесь, что после щелчка мышью по форме на канве отображается один отрезок, соединяющий пиксели с координатами (10, 10) и (300, 300).
Модифицируем программу таким образом, чтобы можно было рисовать произвольные отрезки. Отрезок – это часть прямой, заключенная между двумя точками. Пусть событие нажатие кнопки мыши послужит началом рисования отрезка (переместим графический курсор в точку, на которую указывает курсор мыши), освобождение кнопки мыши – завершением рисования отрезка (нарисуем линию до точки, на которую указывает курсор). Создайте обработчик события OnMouseDown:
procedure TMainF.FormMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
Canvas.MoveTo(X, Y);
end;
Создайте обработчик события OnMouseUp:
procedure TMainF.FormMouseUp(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
Canvas.LineTo(X, Y);
Canvas.MoveTo(X, Y);
end;
Сохраните приложение. Попробуйте с помощью приложения написать свое имя.
Упражнение 6. Создайте приложение, позволяющее изображать кривые линии.
Решение
Закройте предыдущий проект, выполнив команду Close All меню File. Создайте новое приложение, выполнив последовательность команд: File/ New Application. Сохраните новое приложение в папке Exercise3. Файл модуля – под именем Main.pas, файл проекта – Exercise3.dpr.
Измените значения свойств формы следующим образом:
-
Name
MainF
Caption
Кривые линии
Кривая линия это изображение следа курсора мыши. Перемещение курсора мыши возбуждает событие OnMouseMove. Создайте обработчик этого события и введите следующий оператор:
procedure TForm1.FormMouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
begin
Canvas.LineTo(x,y);
end;
Сохраните приложение и запустите его. Убедитесь, что при перемещении курсора мыши на форме изображается линия, началом которой служит левый верхний угол формы. Кроме этого не удается завершить рисование кривой.
Устраним этот недостаток. Обработчик события OnMouseMove в параметре Shift получает состояние клавиш Ctrl, Alt, Shift и кнопок мыши. Для определенности положим, что линию будем рисовать в том случае, когда нажата левая кнопка мыши. Измените обработчик события следующим образом:
procedure TForm1.FormMouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
begin
if ssLeft in Shift then Canvas.LineTo(x, y)
{если нажата левая кнопка мыши, то рисуем линию}
else Canvas.MoveTo(x, y);
{иначе перемещаем графический курсор без следа}
end;
Сохраните проект и запустите его. Проверьте, что линия рисуется только тогда, когда перемещение мыши происходит с нажатой левой кнопкой.
Упражнение 7. Напишите приложение, которое изображает прямоугольники (эллипсы).
Решение
Закройте предыдущий проект, выполнив команду Close All меню File. Создайте новое приложение, выполнив последовательность команд: File/ New Application. Сохраните новое приложение в папке Exercise4. Файл модуля – под именем Main, файл проекта – Exercise4.
Измените свойства формы следующим образом:
-
Name
MainF
Caption
Прямоугольники
В классе TCanvas определен метод Rectangle(x1,y1,x2,y2), в котором параметры задают координаты противоположных вершин прямоугольника (т.е. принадлежащих одной из его диагоналей). Нажатие кнопки мыши (событие OnMouseDown) фиксирует начало рисования прямоугольника, и соответственно определяет координаты первой точки, а освобождение кнопки (событие OnMouseUp) – окончание рисования прямоугольника, и соответственно определяет координаты второй точки. Создайте обработчики этих событий и введите следующие операторы:
procedure TMainF.FormMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
x1:=x;
y1:=y;
end;
procedure TMainF.FormMouseUp(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
Canvas.Rectangle(x1,y1,x,y); {Canvas.Ellipse(x1,y1,x,y)}
end;
Переменные x1 и y1 являются глобальными, но их использование ограничивается пределами данного модуля, поэтому опишите их в разделе private класса TMainF.
Удостоверьтесь в правильности работы программы.
Упражнение 8. Напишите приложение, которое позволяет рисовать ломаные линии
Решение
Создайте новое приложение и сохраните его в папке Exercise5. Файл модуля – под именем Main.pas, файл проекта – Exercise5.dpr.
Измените свойства формы следующим образом:
-
Name
MainF
Caption
Ломанные линии
Объединение отрезков A1A2, A2A3, …, An-1An образуют ломаную A1A2A3…An. Начало ломаной – это точка A1, конец – точка An. Для рисования ломаной нужно задать ее начало, затем нарисовать звенья (отрезки, причем конец одного является началом другого) и, наконец, завершить ломаную (отметить ее конец).
Начало (конец) рисования ломаной линии свяжем с событием OnDblClick. Введем логическую переменную Draw: ее значение, равное True, будет обозначать рисование ломаной, False – завершение ломаной (не забудьте ее описать)
Создайте обработчик события OnDblClick:
procedure TForm1.FormDblClick(Sender: TObject);
begin
Draw:=not Draw;
end;
В обработчике события OnMouseDown будем рисовать звенья ломаной, если значение переменной Draw равно True и перемещать графический курсор, в противном случае:
procedure TForm1.FormMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
if Draw then Canvas.LineTo(x,y)
else Canvas.MoveTo(x,y);
end;
Сохраните проект, используя написанное приложение, попробуйте изобразить треугольник, четырехугольник и пятиугольник.