- •Объекты Microsoft Access
- •Объект Application
- •Объект Application, примеры
- •Объект Collection
- •Пример использования объекта Collection
- •Объект Control
- •Семейство Controls
- •Объект Control, семейство Controls, пример
- •Объект Debug
- •Объект DoCmd
- •Объект DoCmd, пример
- •Объект Err
- •Пример использования объекта Err
- •Объект Form
- •Семейство Forms
- •Объект Form, семейство Forms, примеры
- •Семейство ItemsSelected
- •Семейство ItemsSelected, примеры
- •Объект Module
- •Семейство Modules
- •Объект Module, семейство Modules, пример
- •Объект Page
- •Семейство Pages
- •Объект Page, семейство Pages, пример
- •Объект Reference
- •Семейство References
- •Объект Reference, семейство References, пример
- •Объект Report
- •Семейство Reports
- •Объект Report, семейство Reports, примеры
- •Объект Screen
- •Объект Screen, пример
Объекты Microsoft Access
Application |
|||||||
Forms |
Reports |
Modules |
References |
Screen |
DoCmd |
||
Controls |
Modules |
Controls |
Modules |
|
|
|
|
Application, Screen, DoCmd – только объект, остальные – объект и семейство.
Объект Application
Объект Application (приложение) представляет активное приложение Microsoft Access. Cодержит все объекты Microsoft Access и семейства, в том числе семейство Forms, семейство Reports, семейство Modules, семейство References, объект Screen и объект DoCmd.
Объект Application используется для вызова методов или определения свойств, относящихся ко всему приложению Microsoft Access. Например, метод SetOption объекта Application позволяет определить из программы Visual Basic общие параметры базы данных.
Пример. Показывает, как установить флажок Строка состояния в группе Отображение на экране на вкладке Вид диалогового окна Параметры.
Application.SetOption "Строка состояния", True
Microsoft Access поддерживает программирование объектов, называемое программированием OLE. Допускается управление объектами Microsoft Access из другого приложения, также поддерживающего программирование объектов, которое осуществляется с помощью объекта Application. Например, Microsoft Visual Basic является компонентом ActiveX. Пользователь Visual Basic имеет возможность открыть базу данных Microsoft Access и выполнять действия с ее объектами. Для этого необходимо сначала создать в Microsoft Visual Basic ссылку на библиотеку объектов Microsoft Access 8.0, затем следует создать новую копию класса Application и связать с ним объектную переменную, как показано ниже:
Dim appAccess As New Access.Application
В приложениях, не поддерживающих ключевое слово New, можно создать новую копию класса Application с помощью функции CreateObject:
Dim appAccess As Object
Set appAccess = CreateObject("Access.Application.8")
После создания новой копии класса Application становится возможным открытие базы данных или создание новой базы данных с помощью методов OpenCurrentDatabase или NewCurrentDatabase. Далее следует определить свойства объекта Application и вызывать его методы. После возвращения ссылки на объект DBEngine с помощью свойства DBEngine объекта Application разрешается доступ ко всем объектам доступа к данным DAO (Data Access Objects) и семействам с помощью этой ссылки.
Объект Application позволяет управлять другими объектами Microsoft Access. Например, с помощью метода OpenForm объекта Microsoft Access DoCmd можно открыть форму Microsoft Access из Microsoft Excel:
appAccess.DoCmd.OpenForm "Заказы"
Объект Application, примеры
Пример 1. Выводятся текущие значения некоторых свойств объекта Application, задается значение параметра Скрытые объекты и осуществляется выход из приложения с сохранением всех объектов:
Sub ApplicationInformation()
' Выводит имя и тип текущего объекта.
Debug.Print Application.CurrentObjectName
Debug.Print Application.CurrentObjectType
' Включает параметр "Скрытые объекты" в группе "Отображение на экране".
Application.SetOption "Скрытые объекты", True
' Выход из Microsoft Access с сохранением всех объектов.
Application.Quit acSaveYes
End Sub
Пример 2. Демонстрируется использование Microsoft Access в качестве компонента ActiveX. В Microsoft Excel, Visual Basic или другом приложении, являющемся компонентом ActiveX, создайте ссылку на Microsoft Access. Для этого в меню Сервис окна модуля следует выбрать команду Ссылки и установить флажок Библиотека объектов Microsoft Access 8.0. Затем введите следующую программу в модуль Visual Basic этого приложения и вызовите процедуру GetAccessData.
Имя базы данных и имя отчета передаются в процедуру, которая создает новую копию класса Application, открывает базу данных и печатает указанный отчет.
' Описывает объектную переменную в разделе описаний модуля.
Dim appAccess As Access.Application
Sub GetAccessData()
Dim strDB As String
Dim strReportName As String
' Строка содержит путь базы данных.
strDB = "C:\Program Files\Microsoft Office\Office\Samples\Борей.mdb"
' Строка содержит имя отчета.
strReportName = "Прейскурант"
PrintAccessReport strDB, strReportName
End Sub
Sub PrintAccessReport(strDB As String, strReportName As String)
' Возвращает ссылку на объект Application.
Set appAccess = New Access.Application
' Открывает базу данных в окне Microsoft Access.
appAccess.OpenCurrentDatabase strDB
' Выводит отчет на печать.
appAccess.DoCmd.OpenReport strReportName
MsgBox "По окончании печати " & strReportName & " нажмите OK"
appAccess.CloseCurrentDatabase
Set appAccess = Nothing
End Sub