Объект Page, семейство Pages, пример

В следующей процедуре при выборе пользователем вкладки производится перечисление всех элементов управления каждой вкладки набора.

Для выполнения данного примера создайте новую форму с элементом управления Набор вкладок TabCtl0 и для его свойства Изменение (OnChange) задайте значение [Процедура обработки событий]. Вставьте в модуль формы следующий текст. Перейдите в режим формы и щелкните другую вкладку для перечисления ее элементов управления.

Private Sub TabCtl0_Change()

Dim tbc As Control, pge As Page

Dim ctl As Control

' Возвращает указатель на набор вкладок.

Set tbc = Me!TabCtl0

' Возвращает указатель на текущую страницу.

Set pge = tbc.Pages(tbc.Value)

' Перечисляет элементы управления текущей страницы.

Debug.Print pge.Name & "Элементы управления:"

For Each ctl In pge.Controls

Debug.Print ctl.Name

Next ctl

Debug.Print

End Sub

Объект Reference

Объект Reference указывает на библиотеку типов другого приложения или проекта. Создание объекта Reference сопровождается динамической установкой указателя из программы Visual Basic.

Объект Reference входит в семейство References. Для получения ссылки на объект Reference семейства References используются следующие синтаксические конструкции.

Синтаксис	Описание
References!имяСсылки	Аргумент имяСсылки является названием объекта Reference.
References("имяСсылки")	Аргумент имяСсылки является названием объекта Reference.
References(индекс)	Аргумент индекс является позицией объекта в семействе.

Следующий пример возвращает ссылку на объект Reference, представляющую указатель на библиотеку типов Microsoft Access:

Dim ref As Reference

Set ref = References!Access

Семейство References

Семейство References содержит в себе все объекты Reference, представляющие собой установленные в текущий момент ссылки.

Для просмотра диалогового окна Ссылки, содержащего список ссылок, непосредственно соответствующих объектам Reference семейства References, необходимо выбрать в меню Сервис команду Ссылки. Каждому установленному флажку в списке соответствует один объект Reference. Не установленные флажки не соответствуют объектам, входящим в семейство References. Для перечисления объектов семейства References используется конструкция For Each...Next.

Семейство References принадлежит к объекту Application Microsoft Access.

Объекты Reference семейства References пронумерованы начиная с 1.

Объект Reference, семейство References, пример

Следующий пример создает ссылку на указанную библиотеку типов:

Function ReferenceFromFile(strFileName As String) As Boolean

Dim ref As Reference

On Error GoTo Error_ReferenceFromFile

Set ref = References.AddFromFile(strFileName)

ReferenceFromFile = True

Exit_ReferenceFromFile:

Exit Function

Error_ReferenceFromFile:

MsgBox Err & ": " & Err.Description

ReferenceFromFile = False

Resume Exit_ReferenceFromFile

End Function

Для вызова данной функции допустимо использование процедуры, сходной с нижеследующей, создающей ссылку на элемент управления Календарь:

Sub CreateCalendarReference()

If ReferenceFromFile("C:\Windows\System\Mscal.ocx") = True Then

MsgBox "Указатель установлен успешно."

Else

MsgBox "Указатель не был успешно установлен."

End If

End Sub