5.3.2. Применение ацп с последовательным выходом

Недостатками вышерассмотренной микросхемы АЦП К1113 ПВ1 являются: наличие двух источников питания, для подключения АЦП необходимо 10 разрядов однокристального МК.

В последние годы в микропроцессорной технике получили широкое распространение микросхемы с последовательным выходом. В качестве примера рассмотрим АЦП МАХ1241 (USA) (рис. 56). МАХ 1241 упакована в восьмивыводной (DIP8) корпус, питается напряжением +5В, потребляет ток около 5 мА. Время преобразования данных составляет 8 мкС. Для работы микросхемы требуется источник опорного напряжения. Рассмотрим временную диаграмму работы АЦП, представленную на рис. 57.

До начала преобразования и обмена на входе CS (chip select) должен поддерживаться единичный уровень. Для старта преобразования необходимо установить CS = 0. В течение всего времени преобразования МАХ 1241 поддерживает на своем выходе DOUT уровень логического нуля. После окончания преобразования микросхема переводит DOUT в единичное состояние. В схеме (рис.57) применен прецизионный стабилитрон К142ЕН19, формирующий напряжение 2,5 В на вывод REF микросхемы. Аналоговое напряжение подается на вход AIN. Вход CS предназначен для выбора микросхемы, SCLK – вход синхронизации, DOUT- выход последовательных данных. Для подключения к однокристальному МК используются всего лишь три линии, что является достоинством такого АЦП .

Рис. 56. Условное обозначение АЦП МАХ1241

Перед началом преобразования на входе SCLK также должен быть установлен нулевой уровень. При завершении процесса преобразования однокристальный МК должен сформировать на входе SCLK последовательность не менее чем из 12 единичных импульсов. Фронт первого импульса готовит МАХ 1241 к передаче данных. По спаду импульса на DOUT появляется старший двенадцатый бит данных (B11). МК считывает этот бит и формирует на входе SCLK фронт второго импульса. По спаду этого импульса на выходе DOUT появляется одиннадцатый бит (B10) и так далее. По спаду двенадцатого импульса на выходе DOUT появляется младший бит данных (В0). Спад тринадцатого импульса приводит DOUT в нулевое состояние. Перевод CS в единичное состояние информирует МАХ 1241 о завершении процесса чтения результата преобразования.

Рис. 57. Временные диаграммы работы АЦП МАХ 1241

Следующее преобразование МАХ1241 может осуществить приблизительно через 1 мкС после установки CS = 1. Рассмотрим подпрограмму опроса и получения последовательных данных АЦП МАХ 1241. Временная диаграмма определяет алгоритм управления АЦП микроконтроллером.

<1> SCLK bit P3.4 ; Обозначение битов управления

<2> DOUT bit P3.6 ;

<3 CS bit P3.5 ;

<4>GET_DATA: SETB DOUT ; Установка начального состояния

<5> SETB CS ; АЦП МАХ 1241

<6> CLR SCLK ;

<7> CLR CS ; Запуск АЦП

<8> MOV R7,#8 ;

<9>WAIT_8MKS:NOP ; Задержка на 8 микросекунд, ожидание конца

<10> DJNZ R7,WAIT_8MKS ; оцифровки данных

<11> MOV R0,# 12 ; Загрузка счетчика числа импульсов SCLK

<12>DATA_ACP: SETB SCLK ;

<13> NOP ;

<14> NOP ;

<15> CLR SCLK ;Формирование импульса для чтения бита

<16> NOP ;

<17> NOP ;

<18> MOV C,DOUT ; Чтение бита из АЦП с выхода DOUT

<19> MOV A,R2 ;

<20> RLC A ;

<21> MOV R2,A ; Вталкивание бита данных в слово

<22> MOV A,R3 ; в регистрах R3R2

<23> RLC A ;

<24> MOV R3,A ;

<25> DJNZ R0,DATA_ACP; Если не все биты получены, то продолжить

<26> ANL A,#0FH ; Очистить старшие биты R3R2

<27> MOV R3,A ;

<28> SETB CS ; Конец считывания битов данных

<29> NOP ; Задержка для

<30> NOP ; получения следующих данных

<31> RET ;

Шаги с 4 по 6 устанавливают МАХ 1241 в начальное состояние. После запуска АЦП (шаг 7) необходимо сделать задержку на 8 микросекунд, после чего цифровые последовательные данные готовы для считывания. С 12 по 17 шаг формируется сигнал SCLK. Двенадцатиразрядное данное можно разместить только в двух байтах. В подпрограмме это делается путем помещения битов данных через бит переноса С (шаги с 18 по 24) в регистры R3, R2. Шаги 26 и 27 очищают старшую тетраду регистра R3. Установка CS = 1 (шаг 28) прекращает считывание данных с выхода АЦП. В конце делается задержка для того, чтобы можно было получить новые данные.

Существенными преимуществами МАХ 1241 перед К1113ПВ1 являются: один источник питания, применение всего лишь трех разрядов однокристального МК для управления преобразователем, низкий ток потребления. Эти преимущества дают возможность применения МАХ 1241 в приборах с автономным питанием.

З а д а н и я д л я с а м о с т о я т е л ь н о й р а б о т ы

1. Видоизмените подпрограмму для обеспечения размещения 20 двенадцатиразрядных данных во внутреннем ОЗУ, начиная с адреса 20Н однокристального МК.

2. Разработайте схему и программу, обеспечивающую оцифровку аналоговой информации на выходах двух датчиков, сложение данных и запись результата в 21Н и 20Н ячейки ОЗУ.

Рис. 58. Электрическая принципиальная схема подключения АЦП МАХ 1241