ИЗУЧЕНИЕ ACTIONSCRIPT 3.0 |
78 |
Язык ActionScript и его синтаксис
switch
Инструкция switch полезна, если имеется несколько путей выполнения, которые зависят от одного выражения условия. При этом обеспечивается функциональность, сходная с несколькими последовательными инструкциями if..else if, но несколько более удобочитаемая. Вместо проверки условия для логического значения инструкция switch оценивает выражение и использует результат для определения того, какой блок программного кода следует выполнять. Блоки кода начинаются инструкциями case и заканчиваются инструкциями break. Например, в следующей инструкции switch печатается день недели на основе номера дня, возвращаемого методом Date.getDay().
var someDate:Date = new Date();
var dayNum:uint = someDate.getDay(); switch(dayNum)
{
case 0: trace("Sunday"); break;
case 1: trace("Monday"); break;
case 2: trace("Tuesday"); break;
case 3: trace("Wednesday"); break;
case 4: trace("Thursday"); break;
case 5: trace("Friday"); break;
case 6: trace("Saturday"); break;
default:
trace("Out of range"); break;
}
Повтор
Инструкции цикла позволяют повторно выполнить определенный блок программного кода, используя несколько значений переменных. Adobe рекомендует всегда заключать в фигурные скобки ({}) блок кода. Хотя можно пропустить фигурные скобки, если блок кода содержит всего один оператор, на практике так делать не рекомендуется по той же причине, по которой не рекомендуется и для условий: увеличивается вероятность непреднамеренного исключения оператора из блока кода после его добавления впоследствии. Если впоследствии добавится оператор, который нужно включить в блок кода, но при этом будут пропущены необходимые фигурные скобки, оператор не будет выполняться как часть цикла.
Последнее обновление 12.5.2011.
ИЗУЧЕНИЕ ACTIONSCRIPT 3.0 |
79 |
Язык ActionScript и его синтаксис
for
Инструкция цикла for позволяет итеративно увеличивать переменную в определенном диапазоне значений. Необходимо передать в инструкцию for три выражения: переменную, установленную в качестве исходного значения; инструкцию условия, определяющую окончание цикла; а также выражение, которое изменяет значение переменной для каждого цикла. Например, в следующем программном коде цикл выполняется пять раз. Значение переменной i начинается с 0 и заканчивается 4, выходным значением являются числа от 0 до 4, каждое в своей строке.
var i:int;
for (i = 0; i < 5; i++)
{
trace(i);
}
for..in
Инструкция цикла for..in выполняет итерации для свойства объекта или элементов массива. Например, можно использовать инструкцию цикла for..in для выполнения итераций со значениями свойства родового объекта (свойства объекта не сохраняются в определенном порядке, поэтому свойства могут появляться в кажущемся произвольном порядке).
var myObj:Object = {x:20, y:30}; for (var i:String in myObj)
{
trace(i + ": " + myObj[i]);
}
//output:
//x: 20
//y: 30
Также можно выполнять итерацию по элементам массива.
var myArray:Array = ["one", "two", "three"]; for (var i:String in myArray)
{
trace(myArray[i]);
}
//output:
//one
//two
//three
Единственным действием, которое можно выполнить, является итерация для свойств объекта, если объект является экземпляром запечатанного класса (включая встроенные классы и заданные пользователем классы). Можно выполнить итерацию только для свойств динамического класса. Даже для экземпляров динамического класса можно выполнять только итерацию для свойств, добавляемых динамически.
for each..in
Инструкция цикла for each..in выполняет итерации по элементам коллекции, которые могут быть тегами в объекте XML или XMLList, значениями, содержащимися в свойствах объекта, или элементами массива. Например, как показывает следующая выборка, можно использовать цикл for each..in для итерации по свойствам родового объекта, но в отличие от цикла for..in переменная-итератор в цикле for each..in содержит значение свойства вместо имени свойства.
Последнее обновление 12.5.2011.
ИЗУЧЕНИЕ ACTIONSCRIPT 3.0 |
80 |
Язык ActionScript и его синтаксис
var myObj:Object = {x:20, y:30}; for each (var num in myObj)
{
trace(num);
}
//output:
//20
//30
Можно выполнять итерации по объектам XML или XMLList, как показано в следующем примере.
var myXML:XML = <users> <fname>Jane</fname> <fname>Susan</fname> <fname>John</fname>
</users>;
for each (var item in myXML.fname)
{
trace(item);
}
/* output Jane Susan John
*/
Также можно выполнять итерации по элементам массива, как в следующем примере.
var myArray:Array = ["one", "two", "three"]; for each (var item in myArray)
{
trace(item);
}
//output:
//one
//two
//three
Нельзя выполнять итерацию по свойствам объекта, если он является экземпляром запечатанного класса. Даже для экземпляров динамических классов нельзя выполнять итерации по каким-либо фиксированным свойствам, какими являются свойства, определенные как часть определения класса.
while
Цикл while работает аналогично инструкции if, выполняя повторения до тех пор, пока для условия выдается значение true. Например, в следующем программном коде получаются такие же результаты, что и в примере с циклом for.
var i:int = 0; while (i < 5)
{
trace(i);
i++;
}
Последнее обновление 12.5.2011.