16. Типовые программы обработки строк

В Турбо Паскале, как отмечалось выше, используются данные строкового типа – string. Операции, процедуры и функции, применяемые для этих типов, уже рассмотрены.

Пример 1. Ввести в ЭВМ массив из n (n<=50) слов на английском языке. Расположить их по алфавиту.

Латинские буквы любой ЭВМ, как известно, представляются кодами, которые упорядочены по алфавиту (от "a" до "z"). Слово – это строка, которую можно считать длинным двоичным кодом. Для упорядочения таких кодов можно использовать методы упорядочения чисел, например, метод "пузырька", который был изучен ранее.

Программа будет иметь вид

Program SortW;

Const

Nmax = 20; {Количество слов}

m = 10; {Максимальная длина слова}

Var

W: Array[1..Nmax] of string[m];{Массив для хранения слов}

Wr: String[m]; {Промежуточная переменная для перестановок}

n, i, k : integer;

Begin

WriteLn('Введите количество слов');

Readln(n);

WriteLn('Введите слова');

for i := 1 to n do

ReadLn(w[i]);

for k := 1 to n-1 do

for i := 1 to n-k do

if w[i] > w[i+1] then

begin

Wr := w[i];

w[i] := w[i+1];

w[i+1] := Wr;

end;

WriteLn(Слова, упорядоченные по алфавиту:');

for i:= 1 to n do

WriteLn(w[i]);

End.

В таблицах кодировки символов, содержащих буквы кириллицы, коды букв кириллицы также упорядочены по алфавиту. Студентам предоставляется возможность проверить самостоятельно работу алгоритма на русских словах.

Наиболее типичными задачами обработки текстов являются задачи синтаксического анализа, которые сводятся к выделению слов из предложений и анализу этих слов. В частности, такие задачи решаются при трансляции и компиляции программ с языков высокого уровня.

Основными особенностями структур данных при этом являются следующие.

1. Строка текста или одно слово – одномерный массив символов, а несколько слов – это массив строк (двумерный массив символов).

2. Длина слов в тексте, как правило, неодинакова. Обычно для их разделения используются пробелы. Найти пробел в предложении можно, просматривая последовательно каждый его символ (так как пробел – это тоже символ). Если очередной пробел найден, то предыдущее слово закончилось.

Формирование отдельных слов может быть осуществлено посимвольно, путем объединения слова (строки) с очередным символом, отличным от пробела. Ясно, что вначале формируемое слово должно быть пустым.

Второй метод – запоминание положения первой и последней букв очередного слова в предложении и использование функции Copy для его выделения.

Возможны 2 способа представления текстов:

1) слова разделены всегда одним пробелом;

2) слова разделены одним или несколькими пробелами (общий случай).

Методы выделения слов при этом несколько отличаются.

16.1. Выделение слов из текста (слова разделены одним пробелом)

Условие. Ввести в ЭВМ предложение, в котором слова разделены одним пробелом. Выделить слова, переписать их в массив слов и вывести на экран.

В самом общем виде алгоритм решения задачи может быть таким.

1. Ввести предложение

2. Выделить слова

3. Вывести слова

4. Закончить.

Уточняем пункты алгоритма.

1.1. Ввести предложение

1.2. n = Длина (предложения)

2.1. k = 1; {Номер слова}

2.2. Слово[k] = ''; { пустое слово }

2.3. Для номера буквы в предложении (i) от 1 до n выполнить

2.3.1. Если предл[i] <> ' ', то {очередной символ – не пробел}

Слово[k] = Слово[k] + предл[i]

Иначе {т.е. предл[i]= пробелу; значит, конец предыдущего слова}

а) k = k+1

б) Слово[k] ='' { пустое слово }

3.1. Для номера слова (i) от 1 до k выполнить

3.1.1. Вывести слово[i]

4. Закончить.

Приводимая ниже программа реализует рассмотренный алгоритм.

Program GetSl1;

CONST

m = 50; {Максимальное количество слов в предложении}

VAR

Predl : string; {Предложение}

Slovo : array[1..m] of string; {Массив для слов}

n, k, i: integer; {Вспомогательные переменные}

BEGIN

WriteLn('Вводите предложение:');

ReadLn(Predl);

n := Length(Predl); {п. 1.2.}

k := 1;

Slovo[k] := ''; {Пустое слово – 2 апострофа подряд}

{п. 2.3.}

For i := 1 to n do

If predl[i] <> ' ' then

Slovo[k] := Slovo[k] + Predl[i]

Else

begin

k := k + 1;

Slovo[k] := '';

end;

{п. 3.1.}

WriteLn('Слова из предложения: ');

For i := 1 to k do

WriteLn(Slovo[i]);

END.