23.1.5. Алгоритм и программа представления меню средствами Турбо Паскаля

Реализация меню предполагает выполнение следующих операций:

1) вывод пунктов меню основной парой цветов (фона и текста);

2) вывод выбранного пункта меню другой парой цветов (более яркой);

3) передвижение по меню с помощью традиционных управляющих клавиш;

4) выбор пункта меню для выполнения соответствующей операции;

5) выход из меню.

Три последние операции выполняются с использованием управляющих клавиш, которые имеют следующие коды:

#13 – Enter;

#27 – Esc;

#77 – перемещение курсора влево;

#75 – перемещение курсора вправо;

#72 – перемещение курсора вверх;

#80 – перемещение курсора вниз.

Первым двум кодам соответствует один байт (символ), а остальным – два, причем первый байт у них имеет нулевой код.

Рассмотрим алгоритм и программу на примере горизонтального меню, содержащего не более 5 пунктов. Выбор пункта осуществляется нажатием клавиши Enter, а выход из него и из программы – нажатием клавиши Esc. После выбора пункта для простоты выдается сообщение о том, что он выполняется. Названия пунктов соответствуют названиям операций.

Алгоритм

1.1. Задать пункты меню.

1.2. Очистить экран.

1.3. Начальное положение курсора (пункт меню) pm = 1.

2. Повторять {движение по меню}

2.1. Повторять

2.1.1. Вывести все пункты меню основной парой цветов.

2.1.2. Вывести текущий пункт меню pm другой парой цветов.

2.1.3. Считать символ с клавиатуры {действия пользователя}

2.1.4. Если символ = #0, то {нажата управляющая клавиша}

а) Считать символ {читаем второй код нажатой клавиши}

б) Выбрать символ из значений

#77 : Движение вправо

#75 : Движение влево

Пока Символ не будет равен Esc или Enter.

2.2. Если Символ равен Enter то

Выбрать pm из значений

1 : Вывести: ’Выполняется пункт 1’

2 : Вывести: ’Выполняется пункт 2’

3 : Вывести: ’Выполняется пункт 3’

4 : Вывести: ’Выполняется пункт 4’

5 : Закончить (Символ = Esc)

Пока Символ не будет равен Esc.

3. Закончить

Движение вправо и влево должно быть круговым, т.е. при движении вправо номер пункта увеличивается на 1, пока он не станет равен последнему номеру. После этого номер должен принять значение 1. При движении влево после первого пункта номер должен стать последним.

В программе необходимо задать координаты первого пункта. Если принять названия всех пунктов меню одинаковыми, то начало пункта с номером pm на экране будет иметь координаты:

(xn + (pm - 1)*dl, yn),

где xn и yn – координаты начала первого пункта меню;

dl - длина названия пункта меню (одинаковая для всех пунктов).

Программа для описанного выше алгоритма имеет вид.

Program Gor_Menu;

Uses

Crt;

Const

Dl = 12; {длина названия пункта меню - шаг перемещения}

M = 5; { количество пунктов }

Enter = #13;

Esc = #27;

Var

Punkt : Array[1..m] of String[dl]; { Массив названий }

{ пунктов меню}

pm,i,xn,yn : Integer;

Sim : Char;

Begin

{п. 1.1 }

Punkt[1] := ’ Операция 1 ’;

Punkt[2] := ’ Операция 2 ’;

Punkt[3] := ’ Операция 3 ’;

Punkt[4] := ’ Операция 4 ’;

Punkt[5] := ’ Выход ’;

{ Очистка экрана }

TextBackGround(Blue);

ClrScr;

{ Начальное положение курсора и меню }

pm := 1;

xn := 10;

yn := 3;

Repeat { п. 2 }

Repeat { Цикл движения по меню }

GotoXY(xn,yn);

{ Основные цвета меню }

TextBackGround(Blue);

TextColor(White);

For i := 1 to m do

Write(Punkt[i]);

{ Текущий пункт перекрашиваем }

TextBackGround(Green);

TextColor(Red);

GotoXY(xn+dl*(pm-1),yn);

Write(Punkt[pm]);

{ Ожидаем действий пользователя на клавиатуре}

Sim := Readkey;

If Sim = #0 then

Begin { Управляющая клавиша }

Sim := Readkey;

Case Sim of

#77 : { Движение вправо }

If pm=m then

pm:=1

Else

pm:=pm+1;

#75 : { Движение влево }

If pm=1 then

pm:=m

Else

pm:=pm-1;

End; { Case }

End; { If }

Until (Sim = Enter) Or ( Sim = Esc); { Цикл движения }

If Sim = Enter then

{ Пункт меню выбран }

If pm = m then

Sim := Esc {Выбран последний пункт меню - выход}

Else

Begin

GotoXY(30,10);

Write(’Выполняется ’,Punkt[pm]);

End;

Until Sim = Esc; { Внешний цикл, окончание работы }

GotoXY(30,10);

Writeln(’Конец работы, нажмите любую клавишу ’);

Repeat Until KeyPressed;

End.