12.3. Массивы

Для того, чтобы понять массивы, нужно обладать некоторой культурой математического мышления. Если этот материал покажется вам трудным, не поддавайтесь искушению пропустить его. Настоящего программирования без массивов не бывает, да и большая часть дальнейшего материала без массивов не будет понятна..

Переменные с индексами

В математике широко применяются так называемые индексированные переменные. На бумаге они записываются так:

x₁ x₂ b₈ у_i y_i-6 z_ij z_i+1j

а читаются так: икс первое, икс второе, бэ восьмое, игрек итое, игрек и минус шестое, зет итое житое, зет и плюс первое житое. Поскольку в алфавите Паскаля нет подстрочных букв и цифр, то те же индексированные переменные на Паскале приходится обозначать так:

Х[1] Х[2] B[8] Y[i] Y[i-6] Z[ij] Z[i+1,j]

Зачем нужны индексированные переменные? Их удобно применять хотя бы при операциях над числовыми рядами. Числовой ряд - это просто несколько чисел, выстроенных по порядку одно за другим. Чисел в ряду может быть много и даже бесконечно много.

Возьмем, например, бесконечный ряд чисел Фибоначчи: 1 1 2 3 5 8 13 21 34... Попробуйте догадаться, по какому закону образуются эти числа. Если вы сами не догадались, то я подскажу: каждое из чисел начиная c тpетьего являcтcя cyммoй двух пpeдыдущих. А теперь попробуем записать это утверждение с помощью языка математики. Для этого обозначим каждое из чисел Фибоначчи индексированной переменной таким образом:

Первое число Фибоначчи обозначим так: f[1],

Второе число Фибоначчи обозначим так: f[2] и т. д.

Тогда можно записать, что

f[1]=1 f[2]=1 f[3]=2 f[4]=3 f[5]=5 f[6]=8 ...

Очевидно, что

f[3]=f[3]+f[3],

f[4]=f[2]+f[3],

f[5]=f[3]+f[4]

и т. д.

Как математически одной формулой записать тот факт, что каждое из чисел является суммой двух предыдущих? Математики в индексном виде это записывают так:

f[i]=f[i-2]+f[i-1].

Для иллюстрации подставим вместо i любое число, например 6. Тогда получится:

f[6]=f[6-2]+f[6-l] или

f[6]=f[4]+f[5].

Задание 102

Запишите в индексном виде, как получается из предыдущего числа ряда последующее:

14 18 22 26 .. ..

6 12 24 48 .. ..

3 5 9 17 33 65 .. ..

Вот еще примеры, когда математики предпочитают использовать индексы. Пусть мы на протяжении года каждый день раз в сутки измеряли температуру за окном. Тогда вполне естественно обозначить через t[1] температуру первого дня года, t[2] - второго, ..., t[365] - последнего. Пусть 35 спортсменов прыгали в высоту. Тогда через h[1] можно обозначить высоту, взятую первым прыгуном, h[2] - вторым и т. д.

Одномерные массивы

Одна из типичных задач программирования формулируется примерно так. Имеется большое количество данных, например тех же температур или высот. С этими данными компьютер должен что-нибудь сделать, например, вычислить среднегодовую температуру, количество морозных дней, максимально взятую высоту и т. п. Раньше мы вычисляли подобные вещи и данные вводили в компьютер с клавиатуры одно за другим в одну и ту же ячейку памяти (см. раздел 7.7) Однако практика программирования показывает, что удобно, а часто и необходимо, иметь данные в оперативной памяти сразу все, а не по очереди. Тогда для задачи про температуру нам понадобится 365 ячеек. Эти 365 ячеек мы и назовем массивом. Итак, массивом можно назвать ряд ячеек памяти, отведенных для хранения значений индексированной переменной. Вопрос о том, как большое количество значений оказывается в памяти, отложим на будущее (см. раздел 15.1)

Рассмотрим на простом примере, как Паскаль управляется с массивами. Предположим, в зоопарке живут 3 удава. Известна длина каждого удава в сантиметрах (500, 400 и 600). Какая длина получится у трех удавов, вытянутых в линию?

Обозначим длину первого удава через dlina[1], второго - dlina[2], третьего - dlina[3]. Прикажем Паскалю отвести под эту индексированную переменную массив:

VAR dlina :array [1..3] of Integer;

Здесь array означает массив, или ряд, 1 - первое значение индекса, 3 - последнее. Две точки обозначают диапазон от 1 до 3 (см. раздел 5.7). В целом эту строку можно перевести так: "Отвести в памяти под переменную dlina ряд ячеек типа Integer, пронумерованных от 1 до 3".

Вот программа полностью:

VAR dlina :array [1..3] of Integer;

summa :Integer;

BEGIN

dlina[1]:=500;

dlina[2]:=400;

dlina[3]:=600;

{B этот момент в трех ячейках памяти уже находятся числа и с ними можно выполнять арифметические действия}

summa:=dlina[1]+dlina[2]+dlina[3];

WriteLn(summa)

END.

Если смысл написанного, выше вам неясен, запустите отладочный пошаговый режим выполнения программы, заставив Паскаль показывать вам текущие значения dlina[1], dlina[2], dlina[3], summa.

Теперь запишем ту же программу в предположении, что длины удавов заранее неизвестны и мы их вводим при помощи ReadLn:

VAR dlina :array [1..3] of Integer;

summa :integer;

BEGIN

ReadLn(dlina[1],dlina[2],dlina[3]);

summa:= dlina[1]+dlina[2]+dlina[3];

WriteLn(summa)

END.

Теперь решим ту же задачу в предположении, что удавов не 3, а 1000:

VAR dlina :array [1..1000] of Integer;

summa, i :integer;

BEGIN

{Вводим длины тысячи удавов, хоть это и утомительно:}

for i:=1 to 1000 do ReadLn (dlina[i]);

{Здесь на первом выполнении цикла i=1, и поэтому компьютер выполняет ReadLn(dlina[1]), на втором - i=2, и поэтому компьютер выполняет ReadLn(dlina[2]) и т. д.}

{Определяем суммарную длину тысячи удавов:}

summa=0;

for i:=1 to 1000 do summa=summa+dlina[i]);

WriteLn(summa)

END.

Решим еще одну задачу. Дан ряд из 10 произвольных чисел: a[1], а[2], ..., а[10]. Подсчитать и напечатать суммы троек стоящих рядом чисел: а[1]+а[2]+а[3], а[2]+а[3]+а[4], a[3]+a[4]+a[5], ..., а[8]+а[9]+а[10].

VAR a :array [1..10] of Integer;

i :integer;

BEGIN

for i:=1 to 10 do ReadLn (a[i]);

for i:=1 to 8 do WriteLn (a[i]+a[i+1]+a[i+2])

END.

Задание 103

Напишите программу вычисления среднегодовой температуры (для проверки в компьютере годом можно считать неделю).

Задание 104

Подсчитайте количество морозных дней (когда температура ниже -20 градусов).

Задание 105

Каким по порядку идет самый морозный день?

Задание 106

Вычислить и распечатать первые 30 чисел Фибоначчи.

Двумерные массивы

Поясним суть двумерных массивов на простом примере. Пусть на целом ряде метеостанций, расположенных в разных точках земного шара, в течении многих дней измеряли температуру воздуха. Показания термометров свели в таблицу. Ограничимся для экономии места тремя станциями и четырьмя днями.

	1-й день	2-й день	3-й день	4-й день
Метеостанция 1	-8	-14	-19	-18
Метеостанция 2	25	28	26	20
Метеостанция 3	11	18	20	25

Требуется:

1. Распечатать показания термометров всех метеостанций за 2-й день.

2. Определить среднюю температуру на 3-й метеостанции.

3. Распечатать всю таблицу.

4. Распечатать, в какие дни и на каких метеостанциях температура была в диапазоне 24-26 градусов тепла.

Для этого обозначим показания термометров индексированной переменной с двумя индексами по следующей схеме:

t[1,1] t[1,2] t[1,3] t[1,4]

t[2,1] t[2,2] t[2,3] t[2,4]

t[3,1] t[3,2] t[3,3] t[3,4]

Обратите внимание что первый индекс в скобках обозначает номер строки (метеостанции), второй - номер столбца (дня) прямоугольной таблицы.

Программа:

{В памяти отводим массив из 3*4=12 ячеек под значения типа Integer индексированной переменной t. Будем называть его двумерным массивом:}

VAR t :array[1..3,1..4] of Integer;

s,i,j :Integer;

BEGIN {Зададим значения элементов массива примитивным присваиванием}

t[1,1]:=-8; t[1,2]:=-14; t[1,3]:=-19; t[1,4]:=-18;

t[2,1]:=25; t[2,2]:=28; t[2,3]:=26; t[2,4]:=20;

t[3,1]:=11; t[3,2]:=18; t[3,3]:=20; t[3,4]:=25;

{А теперь распечатаем второй столбец массива}

for i:=1 to 3 do WriteLn(t[i,2]);

{Определим среднее значение элементов третьей строки:}

i:=3;

s:=0;

for j:=1 to 4 do s:=s+t[i,j];

WriteLn(s/4 :10,3);

{Распечатаем всю таблицу:}

for i:=1 to 3 do for j:=1 to 4 do WriteLn (t[i,j]);

{Распечатаем станции и дни с температурой 24-26 градусов.}

for i:=1 to 3 do for j:=1 to 4 do

if (t[i,j]>=24) AND (t[i,j]<=26) then WriteLn ('Станция',i,' день',j)

END.

Задание 107

Вычислить разницу между максимальной и минимальной температурой во всей таблице.

Какие бывают массивы

Массивы могут быть одномерные, двумерные, трехмерные, четырехмерные и т. д.:

:array [1..10] of Integer; - одномерный массив 10 ячеек

:array [1..10,1..5] of Integer; -двумерный массив 50 ячеек

:array [1..10,1..5,1..2] of Integer; - трехмерный массив 100 ячеек

:array [1..10,1..5,1..2,1..3] of Integer; - четырехмерный массив 300 ячеек

Массивы бывают не только числовые, но и символьные, строковые и пр. Подходит любой известный нам тип. Например:

:array [1..50] of Char;

Это означает, что в каждой из 50 ячеек должно находиться не число, а произвольный символ. Еще один пример:

:array [1..50] of String;

Здесь в каждой из 50 ячеек должна находиться строка. Примеры программ с такими массивами мы увидим в разделе 12.13.

Границы индексов в квадратных скобках тоже могут быть разными, например:

:array [20..60] of Real;

Здесь под вещественные числа отводится 41 ячейка,

:array [0..9, -10..30]of Real;

Здесь под вещественные числа отводится 10 * 41 = 410 ячеек. Вообще индексы могут быть не только числовыми, но и любыми порядковыми. Например:

:array ['А'..'Я'] of Real;

Зачем это нужно, будет ясно в разделе 12.8.

Полная синтаксическая информация о массивах будет приведена в разделе 14.8.

Какая польза от массивов при программировании игр? Вряд ли хоть одну серьезную игру можно запрограммировать без применения массивов. Возьмем хотя бы "крестики-нолики" на поле размером 3 на 3. Вам придется рисовать на экране большие клетки, а в них - нолики (кружочки) после ваших ходов и крестики (пересекающиеся линии) после ходов компьютера. Но этого недостаточно. Чтобы компьютер мог поставить крестик в свободном поле, он должен хотя бы знать, в каких клетках крестики и нолики уже стоят. Анализировать для этого информацию о пикселах экрана очень неудобно. Гораздо разумнее заранее организовать VAR а: array[1..3,1..3] of Byte и записывать туда в нужные места нолики после ходов человека и единички после ходов компьютера. Сразу же после записи в массив 0 или 1 программа должна рисовать в соответствующем месте экрана кружок или крестик. Мыслить компьютер мог бы при помощи примерно таких операторов: if (a[1,1]=0) AND (а[1,2]=0) then а[1,3]:=1. Это очевидный защитный ход компьютера.