CHAPTER

Creating Formulas for Financial Applications

It’s a safe bet that the most common use of Excel is to perform calculations involving money. Every day, people make hundreds of thousands of financial decisions based on the numbers that are calculated in a

spreadsheet. These decisions range from simple (Can I afford to buy a new car?) to complex (Will purchasing XYZ Corporation result in a positive cash flow in the next 18 months?). This chapter discusses basic financial calculations that you can perform with the assistance of Excel.

The Time Value of Money

The face value of money may not always be what it seems. A key consideration is the time value of money. This concept involves calculating the value of money in the past, present, or future. It is based on the premise that money increases in value over time because of interest earned by the money. In other words, a dollar invested today will be worth more tomorrow.

For example, imagine that your rich uncle decided to give away some money and asked you to choose one of the following options:

•Receive $8,000 today.

•Receive $9,500 in one year.

•Receive $12,000 in five years.

•Receive $150 per month for five years.

If your goal is to maximize the amount received, you need to take into account not only the face value of the money but also the time value of the money when it arrives in your hands.

IN THIS CHAPTER

A brief overview of the Excel functions that deal with the time value of money

Formulas that perform various types of loan calculations

Formulas that perform various types of investment calculations

An overview of Excel depreciation functions

329

Part II: Working with Formulas and Functions

The time value of money depends on your perspective. In other words, you’re either a lender or a borrower. When you take out a loan to purchase an automobile, you’re a borrower, and the institution that provides the funds to you is the lender. When you invest money in a bank savings account, you’re a lender; you’re lending your money to the bank, and the bank is borrowing it from you.

Several concepts contribute to the time value of money:

•Present Value (PV): This is the principal amount. If you deposit $5,000 in a bank savings account, this amount represents the principal, or present value, of the money you invested. If you borrow $15,000 to purchase a car, this amount represents the principal or present value of the loan. Present Value may be positive or negative.

•Future Value (FV): This is the principal plus interest. If you invest $5,000 for five years and earn 3 percent annual interest, your investment is worth $5,796.37 at the end of the five-year term. This amount is the future value of your $5,000 investment. If you take out a three-year auto loan for $15,000 and make monthly payments based on a 5.25 percent annual interest rate, you pay a total of $16,244.97. This amount represents the principal plus the interest you paid. Future Value may be positive or negative, depending on the perspective (lender or borrower).

•Payment (PMT): This is either principal or principal plus interest. If you deposit $100 per month into a savings account, $100 is the payment. If you have a monthly mortgage payment of $1,025, this amount is made up of principal and interest.

•Interest Rate: Interest is a percentage of the principal, usually expressed on an annual basis. For example, you may earn 2.5 percent annual interest on a bank CD (certificate of deposit). Or your mortgage loan may have a 6.75 percent interest rate.

•Period: This represents the point in time when interest is paid or earned (for example, a bank CD that pays interest quarterly, or an auto loan that requires monthly payments).

•Term: This is the amount of time of interest. A 12-month bank CD has a term of one year. A 30-year mortgage loan has a term of 360 months.

Loan Calculations

This section describes how to calculate various components of a loan. Think of a loan as consisting of the following components:

•The loan amount

•The interest rate

•The number of payment periods

•The periodic payment amount

If you know any three of these components, you can create a formula to calculate the unknown component.

330

Chapter 15: Creating Formulas for Financial Applications

Note

The loan calculations in this section all assume a fixed-rate loan with a fixed term. n

Worksheet functions for calculating loan information

This section describes six commonly used financial functions: PMT, PPMT, IPMT, RATE, NPER, and PV. For information about the arguments used in these functions, see Table 15.1.

TABLE 15.1

	Financial Function Arguments
Function Argument	Description
rate	The interest rate per period. If the rate is expressed as an annual interest rate, you must
	divide it by the number of periods.
nper	The total number of payment periods.
per	A particular period. The period must be less than or equal to nper.
pmt	The payment made each period (a constant value that does not change).
fv	The future value after the last payment is made. If you omit fv, it is assumed to be 0.
	(The future value of a loan, for example, is 0.)
type	Indicates when payments are due — either 0 (due at the end of the period) or 1 (due
	at the beginning of the period). If you omit type, it is assumed to be 0.

PMT

The PMT function returns the loan payment (principal plus interest) per period, assuming constant payment amounts and a fixed interest rate. The syntax for the PMT function is

PMT(rate,nper,pv,fv,type)

The following formula returns the monthly payment amount for a $5,000 loan with a 6 percent annual percentage rate. The loan has a term of four years (48 months).

=PMT(6%/12,48,-5000)

This formula returns $117.43, the monthly payment for the loan. The first argument, rate, is the annual rate divided by the number of months in a year. Also, notice that the third argument (pv, for present value) is negative and represents money owed.

PPMT

The PPMT function returns the principal part of a loan payment for a given period, assuming constant payment amounts and a fixed interest rate. The syntax for the PPMT function is

PPMT(rate,per,nper,pv,fv,type)

331

Part II: Working with Formulas and Functions

The following formula returns the amount paid to principal for the first month of a $5,000 loan with a 6 percent annual percentage rate. The loan has a term of four years (48 months).

=PPMT(6%/12,1,48,-5000)

The formula returns $92.43 for the principal, which is about 78.7 percent of the total loan payment. If I change the second argument to 48 (to calculate the principal amount for the last payment), the formula returns $116.84, or about 99.5 percent of the total loan payment.

Note

To calculate the cumulative principal paid between any two payment periods, use the CUMPRINC function. This function uses two additional arguments: start_period and end_period. In Excel versions prior to Excel 2007, CUMPRINC is available only when you install the Analysis ToolPak add-in. n

IPMT

The IPMT function returns the interest part of a loan payment for a given period, assuming constant payment amounts and a fixed interest rate. The syntax for the IPMT function is

IPMT(rate,per,nper,pv,fv,type)

The following formula returns the amount paid to interest for the first month of a $5,000 loan with a 6 percent annual percentage rate. The loan has a term of four years (48 months).

=IPMT(6%/12,1,48,-5000)

This formula returns an interest amount of $25.00. By the last payment period for the loan, the interest payment is only $0.58.

Note

To calculate the cumulative interest paid between any two payment periods, use the CUMIPMT function. This function uses two additional arguments: start_period and end_period. In Excel versions prior to Excel 2007, CUMIPMT is available only when you install the Analysis ToolPak add-in. n

RATE

The RATE function returns the periodic interest rate of a loan, given the number of payment periods, the periodic payment amount, and the loan amount. The syntax for the RATE function is

RATE(nper,pmt,pv,fv,type,guess)

The following formula calculates the annual interest rate for a 48-month loan for $5,000 that has a monthly payment amount of $117.43.

=RATE(48,117.43,-5000)*12

This formula returns 6.00 percent. Notice that the result of the function is multiplied by 12 to get the annual percentage rate.

332

Chapter 15: Creating Formulas for Financial Applications

NPER

The NPER function returns the number of payment periods for a loan, given the loan’s amount, interest rate, and periodic payment amount. The syntax for the NPER function is

NPER(rate,pmt,pv,fv,type)

The following formula calculates the number of payment periods for a $5,000 loan that has a monthly payment amount of $117.43. The loan has a 6 percent annual interest rate.

=NPER(6%/12,117.43,-5000)

This formula returns 47.997 (that is, 48 months). The monthly payment was rounded to the nearest penny, causing the minor discrepancy.

PV

The PV function returns the present value (that is, the original loan amount) for a loan, given the interest rate, the number of periods, and the periodic payment amount. The syntax for the PV function is

PV(rate,nper,pmt,fv,type)

The following formula calculates the original loan amount for a 48-month loan that has a monthly payment amount of $117.43. The annual interest rate is 6 percent.

=PV(6%/12,48,-117.43)

This formula returns $5,000.21. The monthly payment was rounded to the nearest penny, causing the $0.21 discrepancy.

A loan calculation example

Figure 15.1 shows a worksheet set up to calculate the periodic payment amount for a loan.

On the CD

The workbook described in this section is available on the companion CD-ROM. The file is named loan payment.xlsx.

The loan amount is in cell B1, and the annual interest rate is in cell B2. Cell B3 contains the payment period expressed in months. For example, if cell B3 is 1, the payment is due monthly. If cell B3 is 3, the payment is due every three months, or quarterly. Cell B4 contains the number of periods of the loan. The example shown in this figure calculates the payment for a $25,000 loan at

6.25percent annual interest with monthly payments for 36 months. The formula in cell B6 is

=PMT(B2*(B3/12),B4,-B1)

333

Part II: Working with Formulas and Functions

FIGURE 15.1

Using the PMT function to calculate a periodic loan payment amount.

Notice that the first argument is an expression that calculates the periodic interest rate by using the annual interest rate and the payment period. Therefore, if payments are made quarterly on a threeyear loan, the payment period is 3, the number of periods is 12, and the periodic interest rate would be calculated as the annual interest rate multiplied by 3/12.

In the worksheet in Figure 15.1, range A9:B11 is set up to calculate the principal and interest amount for a particular payment period. Cell B9 contains the payment period used by the formulas in B10:B11. (The payment period must be less than or equal to the value in cell B4.)

The formula in cell B10, shown here, calculates the amount of the payment that goes toward principal for the payment period in cell B9:

=PPMT(B2*(B3/12),B9,B4,-B1)

The following formula, in cell B11, calculates the amount of the payment that goes toward interest for the payment period in cell B9:

=IPMT(B2*(B3/12),B9,B4,-B1)

You should note that the sum of B10 and B11 is equal to the total loan payment calculated in cell B6. However, the relative proportion of principal and interest amounts varies with the payment period. (An increasingly larger proportion of the payment is applied toward principal as the loan progresses.) Figure 15.2 shows the principal and interest portions graphically.

Credit card payments

Do you ever wonder how long it would take to pay off a credit card balance if you make the minimum payment amount each month? Figure 15.3 shows a worksheet set up to make this type of calculation.

334

Chapter 15: Creating Formulas for Financial Applications

FIGURE 15.2

This chart shows the relative interest and principal amounts for the payment periods of a loan.

On the CD

The workbook shown in Figure 15.3 is available on the companion CD-ROM. The file is named credit card payments.xlsx.

Range B1:B5 stores input values. In this example, the credit card has a balance of $1,000, and the lender charges 21.25 percent annual percentage rate (APR). The minimum payment is 2.00 percent (typical of many credit card lenders). Therefore, the minimum payment amount for this example is $20. You can enter a different payment amount in cell B5, but it must be large enough to pay off the loan. For example, you may choose to pay $50 per month to pay off the balance more quickly. However, paying $10 per month isn’t sufficient, and the formulas return an error.

Range B7:B9 holds formulas that perform various calculations. The formula in cell B7, which follows, calculates the number of months required to pay off the balance:

=NPER(B2/12,B5,-B1,0)

The formula in B8 calculates the total amount you will pay. This formula is

=B7*B5

The formula in cell B9 calculates the total interest paid:

=B8-B1

335

Part II: Working with Formulas and Functions

FIGURE 15.3

This worksheet calculates the number of payments required to pay off a credit card balance by paying the minimum payment amount each month.

In this example, it would take about 123 months (more than ten years) to pay off the credit card balance if the borrower made only the minimum monthly payment. The total interest paid on the $1,000 loan would be $1,468.42. This calculation assumes, of course, that no additional charges are made on the account. This example may help explain why you receive so many credit card solicitations in the mail.

Figure 15.4 shows some additional calculations for the credit card example. For example, if you want to pay off the credit card in 12 months, you need to make monthly payments of $93.23. (This amount results in total payments of $1,118.81 with total interest of $118.81.) The formula in B13 is

=PMT($B$2/12,A13,-$B$1)

FIGURE 15.4

Column B shows the payment required to pay off the credit card balance for various payoff periods.

336

Chapter 15: Creating Formulas for Financial Applications

Creating a loan amortization schedule

A loan amortization schedule is a table of values that shows various types of information for each payment period of a loan. Figure 15.5 shows a worksheet that uses formulas to calculate an amortization schedule.

FIGURE 15.5

A loan amortization schedule.

On the CD

This workbook available on the companion CD-ROM. The file is named loan amortization schedule

.xlsx.

The loan parameters are entered into B1:B4, and the formulas beginning in row 9 use these values for the calculations. Table 15.2 shows the formulas in row 9 of the schedule. These formulas were copied down to row 488. Therefore, the worksheet can calculate amortization schedules for a loan with as many as 480 payment periods (40 years of monthly payments).

Note

Formulas in the rows that extend beyond the number of payments return an error value. The worksheet uses conditional formatting to hide the data in these rows. See Chapter 20 for more information about conditional formatting. n

337

Part II: Working with Formulas and Functions

TABLE 15.2

Formulas Used to Calculate an Amortization Schedule

Cell	Formula	Description
A9	=A8+1	Returns the payment number
B9	=PMT($B$2*($B$3/12),$B$4,-$B$1)	Calculates the periodic payment amount
C9	=C8+B9	Calculates the cumulative payment
		amounts
D9	=IPMT($B$2*($B$3/12),A9,$B$4,-$B$1)	Calculates the interest portion of the periodic
		payment
E9	=E8+D9	Calculates the cumulative interest paid
F9	=PPMT($B$2*($B$3/12),A9,$B$4,-$B$1)	Calculates the principal portion of the
		periodic payment
G9	=G8+F9	Calculates the cumulative amount applied
		toward principal
H9	=H8-F9	Returns the principal balance at the end of
		the period

Summarizing loan options by using a data table

The Excel Data Table feature is probably one of the most underutilized tools in Excel. Keep in mind that a data table is not the same as a table (created with Insert Tables Table). A data table is a handy way to summarize calculations that depend on one or two “changing” cells. In this example, I use a data table to summarize various loan options. This section describes how to create one-way and two-way data tables.

Cross-Reference

See Chapter 36 for more information about setting up data tables. n

On the CD

A workbook that demonstrates oneand two-way data tables is available on the companion CD-ROM. The file is named loan data tables.xlsx.

Creating a one-way data table

A one-way data table shows the results of any number of calculations for different values of a single input cell.

Figure 15.6 shows a one-way data table (in B10:I13) that displays three calculations (payment amount, total payments, and total interest) for a loan, using seven interest rates ranging from 7.00 percent to 8.50 percent. In this example, the input cell is cell B2.

338

Chapter 15: Creating Formulas for Financial Applications

FIGURE 15.6

Using a one-way data table to display three loan calculations for various interest rates.

To create this one-way data table, follow these steps:

1.Enter the formulas that return the results for use in the data table. In this example, the formulas are in B6:B8.

2.Enter various values for a single input cell in successive columns. In this example, the input value is interest rate, and the values for various interest rates appear in C10:I10.

3.Create a reference to the formula cells in the column to the left of the input values.

In this example, the range B11:B13 contains simple formulas that reference other cells. For example, cell B11 contains the following formula:

=B6

4.Select the rectangular range that contains the entries from the previous steps. In this example, select B10:I13.

5.Choose Data Data Tools What-If Analysis Data Table. Excel displays the Data Table dialog box, shown in Figure 15.7.

FIGURE 15.7

The Data Table dialog box.

6.For the Row input cell field, specify the cell reference that corresponds to the variable in your Data Table column header row. In this example, the Row input cell is B2.

7.Leave the Column input cell field empty. The Column input field is used for two-way data tables, described in the next section.

339

Part II: Working with Formulas and Functions

8.Click OK. Excel inserts an array formula that uses the TABLE function with a single argument.

9.(Optional) Format the data table. For example, you may want to apply shading to the row and column headers.

Note that the array formula is not entered into the entire range that you selected in Step 4. The first column and first row of your selection are not changed.

Tip

When you create a data table, the leftmost column of the data table (the column that contains the references entered in Step 3) contains the calculated values for the input cell. In this example, those values are repeated in column D. You may want to hide the values in column B by making the font color the same color as the background. n

Creating a two-way data table

A two-way data table shows the results of a single calculation for different values of two input cells. Figure 15.8 shows a two-way data table (in B10:I16) that displays a calculation (payment amount) for a loan, using seven interest rates and six loan amounts.

To create this two-way data table, follow these steps:

1.Enter a formula that returns the results that will be used in the data table. In this example, the formula is in cell B6. The formulas in B7:B8 are not used.

2.Enter various values for the first input in successive columns. In this example, the first input value is interest rate, and the values for various interest rates appear in C10:I10.

FIGURE 15.8

Using a two-way data table to display payment amounts for various loan amounts and interest rates.

340

Chapter 15: Creating Formulas for Financial Applications

3.Enter various values for the second input cell in successive rows, to the left and below the input values for the first input. In this example, the second input value is the loan amount, and the values for various loan amounts are in B11:B16.

4.Create a reference to the formula that will be calculated in the table. This reference goes in the upper-left corner of the data table range. In this example, cell B10 contains the following formula:

=B6

5.Select the rectangular range that contains the entries from the previous steps. In this example, select B10:I16.

6.Choose Data Data Tools What-If Analysis Data Table. Excel displays the Data Table dialog box. (Refer to Figure 15.7.)

7.For the Row Input Cell field, specify the cell reference that corresponds to the first input cell. In this example, the Row Input cell is B2.

8.For the Column Input Cell field, specify the cell reference that corresponds to the second input cell. In this example, the ColumnInput cell is B1.

9.Click OK. Excel inserts an array formula that uses the TABLE function with two arguments.

After you create the two-way data table, you can change the calculated cell by changing the cell reference in the upper-left cell of the data table. In this example, you can change the formula in cell B10 to =B8 so that the data table displays total interest rather than payment amounts.

Tip

If you create very large data tables, the calculation speed of your workbook may be slowed down. Excel has a special calculation mode for calculation-intensive data tables. To change the calculation mode, choose Formulas Calculation Calculation Options Automatic Except For Data Tables. n

Calculating a loan with irregular payments

So far, the loan calculation examples in this chapter have involved loans with regular periodic payments. In some cases, loan payback is irregular. For example, you may loan some money to a friend without a formal agreement as to how he will pay the money back. You still collect interest on the loan, so you need a way to perform the calculations based on the actual payment dates.

Figure 15.9 shows a worksheet set up to keep track of such a loan. The annual interest rate for the loan is stored in cell B1 (named APR). The original loan amount and loan date are stored in row 5. Formulas, beginning in row 6, track the irregular loan payments and perform calculations.

341

Part II: Working with Formulas and Functions

FIGURE 15.9

This worksheet tracks loan payments that are made on an irregular basis.

Column B stores the payment amount made on the date in column C. Notice that the payments are not made on a regular basis. Also, notice that in two cases (row 11 and row 24), the payment amount is negative. These entries represent additional borrowed money added to the loan balance. Formulas in columns D and E calculate the amount of the payment credited toward interest and principal. Columns F and G keep a running tally of the cumulative payments and interest amounts. Formulas in column H compute the new loan balance after each payment. Table 15.3 lists and describes the formulas in row 6. Note that each formula uses an IF function to determine whether the payment date in column C is missing. If so, the formula returns an empty string, so no data appears in the cell.

TABLE 15.3

Formulas to Calculate a Loan with Irregular Payments

Cell	Formula	Description
D6	=IF(C6<>””,(C6-	The formula calculates the interest, based on the payment date.
	C5)/365*H5*APR,””)
E6	=IF(C6<>””,B6-D6,””)	The formula subtracts the interest amount from the payment to
		calculate the amount credited to principal.

342